Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

1. Anzahl Wörter in einer Zelle oder einem Zellbereich ermitteln

Um die Anzahl Wörter in einer Zelle oder einem Zellbereich zu ermitteln, muss man normalerweise nur wissen, wieviele Zwischenräume vorkommen: es gibt genau ein Wort mehr als es Zwischenräume gibt.


1.1. Wie ermittelt man die Anzahl Zwischenräume?

Man zählt mit der Funktion LÄNGE() die Anzahl Zeichen, die ein Text hat und vergleicht diese Zahl mit der Anzahl Zeichen, die übrigbleiben, wenn man alle Leerzeichen weglässt. 1

1.2. Wie eliminiert man Leerzeichen aus einem Text?

Im Grunde einfach mit der Funktion WECHSELN(). Um jedoch sicherzugehen, dass nicht doppelte Leerzeichen oder Leerzeichen am Anfang und Ende des Textes zu falschen Ergebnissen führen, muss der Text zunächst mit Hilfe der Funktion GLÄTTEN() um diese überflüssigen Leerzeichen bereinigt werden.

1.3. Formelaufbau

A

B

1

  Wie zählt   man die Anzahl  Wörter in einer Zelle?  

Formel in Spalte A:

2

Wie zählt man die Anzahl Wörter in einer Zelle

=GLÄTTEN(A1)

3

46

=LÄNGE(GLÄTTEN(A1))

4

WiezähltmandieAnzahlWörterineinerZelle

=WECHSELN(GLÄTTEN(A1);" ";"")

5

38

=LÄNGE(WECHSELN(GLÄTTEN(A1);" ";""))

6

9

=LÄNGE(GLÄTTEN(A1))-LÄNGE(WECHSELN(GLÄTTEN(A1);" ";""))+1

7

Für den Fall, dass eine Zelle auch einfach nur Leerzeichen enthalten kann:

8

9

=LÄNGE(GÄTTEN(A1))-LÄNGE(WECHSELN(GLÄTTEN(A1);" ";""))+WENN(WECHSELN(A1;" ";"")<>"";1)

9

oder:

10

9

=WENN(WECHSELN(A1;" ";"")="";0; LÄNGE(GLÄTTEN(A1))-LÄNGE(WECHSELN(GLÄTTEN(A1);" ";""))+1)

1.4. Zählen der Wörter eines ganzen Zellbereichs

(./) Getestet mit OpenOffice.org 2.0

Um einen ganzen Zellbereich zu bearbeiten, benötigt man Matrixfunktionen. Das kann entweder die offizielle Matrixfunktion SUMMENPRODUKT() sein. Oder man benutzt die Funktion SUMME(), die man dann aber mit SHIFT+CTRL+RETURN abschliessen muss, damit das Programm sie als Matrixformel erkennt.

A

B

1

  Wie zählt   man die Anzahl  Wörter in einer Zelle  

  oder   in einem  Zellbereich?  

2

13

{=SUMME((LÄNGE(GLÄTTEN(A1:B1))-LÄNGE(WECHSELN(GLÄTTEN(A1:B1);" ";""))+1)* (WECHSELN(A1:B1;" ";"")<>""))}

3

oder:

4

13

=SUMMENPRODUKT(LÄNGE(GLÄTTEN(A1:B1))- LÄNGE(WECHSELN(GLÄTTEN(A1:B1);" ";""))+1; WECHSELN(A1:B1;" ";"")<>"")

2. siehe auch


KategorieCalc KategorieTipps KategorieHowto

  1. Das gleiche Prinzip ist natürlich auch anwendbar auf andere Trennzeichen, wie Kommata oder Strichpunkte (1)


LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28