Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

(./) OOo2.3

Die Funktion PIVOTDATENZUORDNEN (engl. GETPIVOTDATA) bezieht sich auf die Ergebnistabelle des Datenpiloten. Die Funktion erlaubt es, auf einzelne Werte der Tabelle mit den Bezeichnungen der Kategorien, d.h. Spalten- und Zeilenbeschriftungen, zuzugreifen anstatt direkte Zelladressen anzugeben.

Den Beispielen liegt die rechts stehende Datenliste zu Grunde. Alle Beispiele sind in dem Dokument beispiele.ods enthalten.

DatenKreuztabelle.png

1. Kreuztabelle

Die Daten der abgebildeten Liste werden durch den Datenpiloten in einer Kreuztabelle zusammengefasst. Die Elementnamen der Kategorie „Anwender“ stehen untereinander, die der Kategorie „Region“ nebeneinander. Das Innere der Kreuztabelle enthält die Summen aus dem Datenfeld „verkaufte Einheiten“, getrennt nach den Elementen der Kategorien.

DatenpilotA.png

Dieses Layout erzeugt die rechts stehende Datenpilottabelle. (Sie wurde über die Zellen-Formatvorlagen etwas gestaltet.)

DatenpilotA_Ausgabe.png

Für die PIVOTDATENZUORDNEN-Funktion gibt es zwei Schreibweisen:

1.1. Syntax kompatibel zu Excel

=PIVOTDATENZUORDNEN("verkaufte Einheiten";F2)  liefert den Wert 1136.

Der erste Parameter gibt den Datenfeldnamen an, auf den sich die Aggregat-Funktion bezieht, also was im Datenpiloten in der Liste Datenfelder liegt.

Der zweite Parameter gibt die Zelladresse irgendeiner Zelle in der Datenpilottabelle an. Dieser Parameter dient dazu, die Tabelle zu identifizieren. Sie könnten ja zu einer Datenliste mehrere Datenpilottabellen gleichzeitig in Ihrem Tabellendokument benutzen.

Wenn keine weiteren Angaben folgen, wird das Datenpilotergebnis ausgegeben, das rechts unten in der Tabelle steht.

Fügen Sie als weitere Parameter jeweils ein Paar "Kategoriename";"Elementname" hinzu, um sich auf andere Felder der Tabelle zu beziehen. Die Bezeichnungen werden jeweils in Anführungszeichen eingeschlossen. Trennen Sie die Parameter wie üblich mit Semikolon voneinander.

=PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Region";"Inland")  liefert den Wert 571.

=PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Region") führt zur Anzeige #REF!, weil OOo nicht weiß, welches der Teilergebnisse EU, Inland oder sonstige gewünscht wird.

Durch ein weiteres Paar Parameter erhalten Sie die Werte aus dem Innern der Kreuztabelle. =PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Anwender";"geschäftlich";"Region";"Inland")  liefert den Wert 344.

Die Angaben dürfen sich nicht widersprechen; =PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Region";"Inland";"Region";"EU") führt zur Anzeige #REF! und stellt nicht die Addition der Werte dar.

1.2. Besondere Schreibweise in Calc

Diese Schreibweise hat den Aufbau =PIVOTDATENZUORDNEN(Zelladresse, Bedingung). Die Zelladresse dient wieder dazu, die Tabelle zu identifizieren. Die Bedingung wird als Ganzes in Anführungszeichen eingeschlossen und enthält eine Folge von Elementnamen unterschiedlicher Kategorien, die mit Leerzeichen voneinander getrennt sind.

Wenn die Elementnamen aus mehreren Wörtern bestehen und bei unterschiedlichen Elementnamen gleiche Wörter vorkommen, dann schließen Sie den gesamten Elementnamen mit einfachen Anführungszeichen ein.

Obige Beispiele lauten in dieser Schreibweise =PIVOTDATENZUORDNEN(F2;"") =PIVOTDATENZUORDNEN(F2;"Inland") =PIVOTDATENZUORDNEN(F2;"geschäftlich Inland")  Den Namen der Kategorie brauchen Sie nur hinzu zufügen, wenn Elementnamen mehrmals vorkommen. Die Schreibweise ist dann Kategorie[Elementname]. Dieses ist nur bei den tatsächlich doppelten nötig. Zum Beispiel ist =PIVOTDATENZUORDNEN(F2;"EU sonstige") nicht möglich. Sie müssen angeben zu welcher Kategorie der Wert sonstige gehört. =PIVOTDATENZUORDNEN(F2;"Region[sonstige]")  liefert 244. =PIVOTDATENZUORDNEN(F2;"EU Anwender[sonstige]")  liefert 91.

2. Liste mit Teilergebnissen

2.1. Details ein- und ausblenden

Durch rechts stehendes Layout im Datenpiloten erhält man ein Gliederungsformat. Zu jedem Unterpunkt in der ersten Spalte werden Details in der zweiten Spalte aufgeführt. Wenn die Eigenschaft Drilldown zu Details zulassen angekreuzt ist – Dialog durch die Schaltfläche Zusätze erweitern –, kann man durch Doppelklick auf den Unterpunkt in der ersten Spalte die Details ein- und ausblenden.

DatenpilotB.png

Details eingeblendet

DatenpilotB_Ausgabe.png

Bei ausgeblendeten Details werden die Ergebnisse zusammengefasst. Dazu wird die gleiche Aggregat-Funktion benutzt wie für Gesamt Ergebnis.

DatenpilotB_Ausgabe_eingeklappt.png

Die Funktion PIVOTDATENZUORDNEN kann nur Werte liefern, die tatsächlich angezeigt werden. Daher führt die Formel =PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Region";"EU")  bzw. in der anderen Schreibweise =PIVOTDATENZUORDNEN(F2;"EU")  bei eingeblendeten Details zu einem #REF!-Fehler, weil die Teilsumme EU nicht verfügbar ist; bei ausgeblendeten Details liefert sie 321.

Umgekehrt liefert =PIVOTDATENZUORDNEN(F2;"EU geschäftlich")  bei eingeblendeten Details den Wert 142 und bei ausgeblendeten Details einen Fehler.

2.2. Unterschiedliche Aggregat-Funktionen

Für die Bildung von Teilergebnissen können Sie die Aggregat-Funktion unabhängig von der zentralen Aggregat-Funktion festlegen. Diese Einstellungen erreichen Sie über die Schaltfläche Optionen im Datenpiloten.

DatenpilotTeilergebnisse.png

Die Datenpilottabelle hat nun jeweils eine zusätzliche Zeile mit dem Teilergebnis.

DatenpilotTeilergebnisse_Ausgabe.png

Um diesen Wert zu erreichen, können Sie aber nicht die Form =PIVOTDATENZUORDNEN("verkaufte Einheiten";F2;"Region";"EU") benutzen, weil diese Form von der zentralen Aggregat-Funktion, hier Summe, ausgeht. Hier wird jedoch der Mittelwert berechnet. In dieser Syntax-Variante ist das Feld überhaupt nicht erreichbar.

In der zweiten Syntax-Variante können Sie jedoch angeben, welche Aggregat-Funktion benutzt wird. =PIVOTDATENZUORDNEN(F2;"Region[EU;Average]")  Dazu nehmen Sie die ausführliche Schreibweise mit Kategoriebezeichner und hängen die Aggregat-Funktion mit einem Semikolon getrennt an den Elementnamen an. Zur Zeit (August 2007) muss die Funktion mit dem englischen Bezeichner angegeben werden. Ob dies ein Programmfehler ist, ist noch zu klären http://www.openoffice.org/issues/show_bug.cgi?id=80659.

3. Mehrere Datenfelder

Mit dem rechts stehenden Layout bilden Sie gleichzeitig eine Zusammenfassung über die Kategorie Anwender und eine über die Kategorie verkaufte Einheiten.

DatenpilotZweiDatenfelder.png

Dies führt zu der rechts abgebildeten Tabelle.

DatenpilotZweiDatenfelder_Ausgabe.png

In der PIVOTDATENZUORDNEN-Funktion geben Sie an, auf welche Kategorie sich die Ergebnisse beziehen sollen. Für die erste Syntaxvariante beispielsweise =PIVOTDATENZUORDNEN("Anwender";F2) =PIVOTDATENZUORDNEN("verkaufte Einheiten";F5;"Region";"EU")  und für die zweite Variante entsprechend =PIVOTDATENZUORDNEN(F2;"Anwender") =PIVOTDATENZUORDNEN(F2;"verkaufte Einheiten EU") 

Die folgenden Abbildungen zeigen die Berechnung unterschiedlicher Zusammenfassungen der selben Kategorie. Mit STRG-Taste wählen Sie diese im Datenpiloten aus.

DatenpilotZweiErgebnisse.png Auswahlaggregatfunktion.png

DatenpilotZweiErgebnisse_Ausgabe.png

Für den Zugriff auf die Einzelwerte, müssen Sie angeben, welche Zusammenfassung Sie haben möchten. Dazu schreiben Sie die Funktion mit Bindestrich vor den Kategorienamen – wie in der Datenpilottabelle. Für die erste Syntaxvariante schreiben Sie beispielsweise =PIVOTDATENZUORDNEN("Summe - verkaufte Einheiten";F2) =PIVOTDATENZUORDNEN("Mittelwert - verkaufte Einheiten";F2;"Region";"EU")  In der zweiten Syntaxvariante lautet es dann =PIVOTDATENZUORDNEN(F2;"Summe - verkaufte Einheiten") =PIVOTDATENZUORDNEN(F2;"Mittelwert - verkaufte Einheiten EU") 

4. Vergleich zu Referenzieren über Zelladressen

4.1. Vorteile

Die mit PIVOTDATENZUORDNEN berechneten Werte sind unabhängig von der Anordnung in der Datenpilottabelle. Beispiele:

Wenn Werte durch Filtern oder Aus- und Einblenden nicht zur Verfügung stehen, wird bei der PIVOTDATENZUORDNEN-Funktion ein Fehler erzeugt. Beim Benutzen von Zelladressen würde mit falschen Werten weiter gerechnet.

4.2. Nachteile

Sie können keine Zellbereiche als Ausgabe erhalten, sondern nur einzelne Werte.

5. Siehe auch

DatenPilot



LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28