Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

Dieses OpenOffice.org 2.0 Installationsscript für Windows ist in einem Unternehmen mit ca. 500 Clients im Einsatz. Es werden die entpackten Installationsdateien aus der Datei OOo_2.0.0_Win32Intel_install_de.exe benötigt. Diese Dateien werden bei der manuellen Installation auf dem Desktop entpackt. Desweiteren ist es sinnvoll einen kompletten Client vollständig mit funktionierender Rechtschreibprüfung und eventuellen Vorlagen einzurichten und von dort den Anwendungsdatenordner mit der kompletten Ordnerstruktur einschließlich der Datei OpenOffice.org2\user\registry\data\org\openoffice\Setup.xcu auf den Fileserver zu kopieren. Die Benutzer müssen sich beim ersten Start von OOo dann nicht mehr durch die Dialoge klicken. Das gilt auch für den dict Ordner (Rechtschreibprüfung), welcher im Programmverzeichnis unter share liegt. Die Installation nimmt als Zielllaufwerk D:, somit müssen dem Benutzer nicht besondere Zugriffsrechte auf c:\programme\ gegeben werden.

<!> Einige längere Zeilen enthalten einen Zeilenumbruch hier in der Darstellung, dieser muss natürlich wieder entfernt werden.

<!> Das Betriebssystem sollte auf einem aktuellen Stand sein bzw. einen aktuellen Windows Installer drauf haben, damit die Variable INSTALLLOCATION funktioniert!

OpenOffice2_Installation.cmd

@echo off
REM Vollautomatische OpenOffice.org 2.0 Installation
REM 05.12.2005 N.Schulze - Version 0.05
REM Dieser Script steht unter der GPL Lizenz
REM Die OOo Installationsdateien muessen entpackt
REM im angegebenen Verzeichnis liegen.
REM Die Dateien werden bei der manuellen
REM Installation auf dem Desktop entpackt
REM Die Dateien kann man verwenden.
REM Installation erfolgt auf Laufwerk D:
REM Es werden vom Fileserver einige Dateien
REM kopiert. Die Dateien sollten vorher
REM von einem funktionierenden Client
REM auf dem Fileserver kopiert werden.

ECHO OpenOffice.org 2.0 Installation
ECHO 05.12.2005 N.Schulze


if not exist d: goto fehler1
if not exist e: goto fehler2
if exist z:\ net use z: /delete >nul
REM Pruefen ob schon installiert?
if exist "D:\Programme\OpenOffice.org\program\setup.ini" goto oldooo
REM Pruefen ob Dateien auf lokalen Server liegen
if not exist %logonserver%\Freigabe\OpenOffice.org\OOo\openofficeorg20.msi goto zentral
if not exist z: net use z: %logonserver%\Freigabe /persistent:no >NUL 2>NUL
if exist z: goto starten

REM Installation vom zentralen Server
:zentral
if not exist z: net use z: \\zentralerfileserver\freigabe /persistent:no >NUL 2>NUL
if not exist z: goto fehler3

:starten
REM Vorbereitungen
if not exist "e:\Eigene Dateien" mkdir "e:\Eigene Dateien"
if not exist z:\OpenOffice.org\OOo\openofficeorg20.msi goto fehler3
REM Automatische Installation auf D:
ECHO Starte Installation .... Bitte warten ...
start /wait z:\OpenOffice.org\OOo\openofficeorg20.msi INSTALLLOCATION=d:\Programme\OpenOffice.org /passive

REM Rechtschreibkorekturdateien kopieren
xcopy z:\OpenOffice.org\OOo\dict\ooo\*.* d:\programme\OpenOffice.org\share\dict\ooo\*.* /c/e/k/h/Y
REM Anwendungsdatenvorlage ins Programmverzeichnis kopieren
if not exist d:\programme\OpenOffice.org\Anwendungsdaten mkdir d:\programme\OpenOffice.org\Anwendungsdaten
xcopy z:\OpenOffice.org\OOo\Anwendungsdaten\*.* d:\programme\OpenOffice.org\Anwendungsdaten\*.* /c/e/k/h/Y


if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Writer.lnk" copy "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Writer.lnk" "%ALLUSERSPROFILE%\Desktop\Textverarbeitung.lnk"
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Calc.lnk" copy  "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Calc.lnk" "%ALLUSERSPROFILE%\Desktop\Tabellenkalkulation.lnk"
mkdir "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org"
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Writer.lnk" copy "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Writer.lnk" "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org\Textverarbeitung.lnk"
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Calc.lnk" copy  "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Calc.lnk" "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org\Tabellenkalkulation.lnk"
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Base.lnk" copy "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Base.lnk" "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org\Datenbank.lnk"
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Impress.lnk" copy  "%ALLUSERSPROFILE%\Startm~1\Programme\OpenOffice.org 2.0\OpenOffice.org Impress.lnk" "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org\Praesentation.lnk"

if exist z:\OpenOffice.org\OOo\Anwendungsdaten\OOo.cmd copy  z:\OpenOffice.org\OOo\Anwendungsdaten\OOo.cmd "%ALLUSERSPROFILE%\Startm~1\Programme\Autostart\"
REM Unter dem aktuellen angemeldeten Benutzer gleich testen
if exist "%ALLUSERSPROFILE%\Startm~1\Programme\Autostart\OOo.cmd" call "%ALLUSERSPROFILE%\Startm~1\Programme\Autostart\OOo.cmd"

REM Dateitypenzuordnung einrichten
:question
echo.
SET /P qmso=? [j/n]: Alle MSOffice Dateitypen OpenOffice.org zuordnen?
IF /I '%qmso%'=='J' GOTO nomsoffice
IF /I '%qmso%'=='N' GOTO ende
GOTO question
:nomsoffice
assoc .xls=opendocument.CalcDocument.1
assoc .xlt=opendocument.CalcDocument.1
assoc .doc=opendocument.WriterDocument.1
assoc .dot=opendocument.WriterDocument.1
assoc .rtf=opendocument.WriterDocument.1
goto ende


:oldooo
echo Vorhandene OpenOffice.org Installation gefunden!
echo Fuer Neuinstallation bitte erst einmal manuell deinstallieren!.
pause
goto ende
:fehler1
echo Partition D: existiert nicht!"
goto ende
:fehler2
echo Partition E: existiert nicht!"
goto ende
:fehler3
echo Keine Installationsquelle gefunden!"
:ende
if exist z:\ net use z: /delete >nul

OOo.cmd: Diese Batch-Datei wird vom Installationsscript in den Autostart-Ordner kopiert

@echo off
REM OpenOffice.org Anwendungsdaten initialisieren
REM  05.12.2005 N.Schulze
REM Prüfen ob schon mal durchgelaufen
if exist "%USERPROFILE%\Anwendungsdaten\OOo20.txt" goto ende
REM Ist OOo auf dem Computer?
if not exist "D:\Programme\OpenOffice.org\program\setup.ini" goto ende

ECHO OpenOffice.org Erstinstallation ... bitte warten

:zentral
REM Anwendungsdaten vom Server in Anwendungsdaten
REM des aktiven Benutzes kopieren
if not exist %logonserver%\freigabe\OpenOffice.org\OOo\Anwendungsdaten\OpenOffice.org2 goto lokal
xcopy /e /Y %logonserver%\freigabe\OpenOffice.org\OOo\Anwendungsdaten "%appdata%" >nul
goto sprung

:lokal
REM Anwendungsdaten vom lokalen Verzeichnis in Anwendungsdaten
REM des aktiven Benutzes kopieren
if not exist D:\Programme\OpenOffice.org\Anwendungsdaten\OpenOffice.org2 goto ende
xcopy /e /Y D:\Programme\OpenOffice.org\Anwendungsdaten "%appdata%" >nul

:sprung
ECHO OOo Installation > "%USERPROFILE%\Anwendungsdaten\OOo20.txt"

:ENDE

Besondere Lizenzbedingungen für Programmcode

This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.



LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28