Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

Dieses OpenOffice.org-Installationsscript für Windows ist in einem Unternehmen mit ca. 500 Clients im Einsatz.

<!> Einige längere Zeilen enthalten einen Zeilenumbruch hier in der Darstellung, dieser muss natürlich wieder entfernt werden.

OpenOffice_Installation.cmd

@echo off
REM OpenOffice.org 1.1.5 Installationsscript
REM Dezentrale Installation
REM 27.09.2005 by Norbert Schulze
REM Dieser Script steht unter der GPL Lizenz
REM Startet eine vollautomatische Installation auf dem Client
REM Benötigt werden die Dateien netinst.ini und autoinst.ini
REM zusammen mit dem Setupverzeichnis auf einem Fileserver
REM Ein Windows Client ab 2000 mit 3 Partitionen c=system, d=appl, e=user
REM Start nur mit Administratorrechten!

ECHO OpenOffice.org Installation

REM Laufwerk D: wird zur Installation benutzt
if not exist d: goto fehler1
REM Laufwerk E: wird für die "Eigenen Dateien" benutzt
if not exist e: goto fehler2
REM Prüfen ob ein Netzlaufwerk Z verbunden ist
REM wenn ja erst mal löschen
if exist z:\ net use z: /delete >nul
REM Prüfen ob OOo schon installiert ist
if exist "D:\Programme\OpenOffice.org\program\setup.exe" goto oldooo
REM Pruefen ob Dateien auf lokalen FILESERVER liegen
if not exist \\FILESERVER\inst\OpenOffice.org\Setup goto zentral
if not exist z: net use z: \\FILESERVER\inst /persistent:no >NUL 2>NUL
if exist z: goto starten

REM Installation vom zentralen Server
:zentral
if not exist z: net use z: \\ZENTRALERFILESERVER\archiv /persistent:no >NUL 2>NUL
if not exist z: goto fehler3

:starten
REM Vorbereitungen
if not exist d:\Programme mkdir d:\Programme
if not exist "e:\Eigene Dateien" mkdir "e:\Eigene Dateien"
if not exist d:\Programme\OpenOffice.org mkdir d:\Programme\OpenOffice.org
if not exist z:\OpenOffice.org\Setup\setup.exe goto fehler3
REM netinst
ECHO Starte Installation .... Bitte warten ...
start /wait z:\OpenOffice.org\Setup\setup.exe -r:z:\OpenOffice.org\netinst.ini
REM Workstation Installation
start /wait D:\Programme\OpenOffice.org\program\setup.exe -r:z:\OpenOffice.org\autoinst.ini
ECHO OOo Installation > "%USERPROFILE%\Anwendungsdaten\OOo115.txt"
xcopy z:\OpenOffice.org\Anwender\*.* d:\programme\OpenOffice.org\Anwender\*.* /c/e/k/h/Y
xcopy z:\OpenOffice.org\de_DE\*.* d:\programme\OpenOffice.org\share\dict\ooo\*.* /c/e/k/h/Y
if exist "%USERPROFILE%\Startm~1\Programme\OpenOffice.org 1.1.5\Textdokument.lnk" copy "%USERPROFILE%\Startm~1\Programme\OpenOffice.org 1.1.5\Textdokument.lnk" "%ALLUSERSPROFILE%\Desktop\"
if exist "%USERPROFILE%\Startm~1\Programme\OpenOffice.org 1.1.5\Tabellendokument.lnk" copy  "%USERPROFILE%\Startm~1\Programme\OpenOffice.org 1.1.5\Tabellendokument.lnk" "%ALLUSERSPROFILE%\Desktop\"
mkdir "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org"
if exist "%USERPROFILE%\Startmen\Programme\OpenOffice.org 1.1.5\Textdokument.lnk" copy "%USERPROFILE%\Startm~1\Programme\OpenOffice.org 1.1.5\*.lnk" "%ALLUSERSPROFILE%\Startm~1\OpenOffice.org\"

exit
:oldooo
echo Alte OpenOffice.org Installation gefunden!
echo Fuer Neuinstallation bitte erst einmal deinstallieren und d:\programme\openoffice.org umbenennen.
net send %computername% Alte OpenOffice.org Installation gefunden! Fuer Neuinstallation bitte erst einmal deinstallieren und d:\programme\openoffice.org umbenennen.
pause
goto ende
:fehler1
net send %computername% Partition D: existiert nicht!"
goto ende
:fehler2
net send %computername% Partition E: existiert nicht!"
goto ende
:fehler3
net send %computername% z:\OpenOffice.org\Setup\setup.exe existiert nicht!"
:ende
if exist z:\ net use z: /delete >nul
exit

netinst.ini: Diese Datei muss auf dem Fileserver im Verzeichnis OpenOffice.org abgelegt werden.

[ENVIRONMENT]
INSTALLATIONMODE=INSTALL_NETWORK
INSTALLATIONTYPE=STANDARD
MIGRATION=NO
DESTINATIONPATH=D:\Programme\OpenOffice.org
LANGUAGELIST=49
[PROCEDURES]

autoinst.ini: Diese Datei muss auf dem Fileserver im Verzeichnis OpenOffice.org abgelegt werden.

[ENVIRONMENT]
INSTALLATIONMODE=INSTALL_WORKSTATION
INSTALLATIONTYPE=WORKSTATION
MIGRATION=NO
DESTINATIONPATH=D:\Programme\OpenOffice.org\Anwender

[JAVA]
JavaSupport=preinstalled_or_none
 
[Windows_Desktop_Integration]
RegisterForMsWord=YES
RegisterForMsExcel=YES
RegisterForMsPowerPoint=NO
RegisterAsDefaultHtmlEditor=NO

Besondere Lizenzbedingungen für Programmcode

This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.


KategorieInstallation


LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28