Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

(./) SO7 OOo1.1

Eine Häufigkeitsverteilung ist eine Tabelle, die jeder Merkmalsausprägung die absolute – und davon abgeleitet auch die relative – Häufigkeit zuordnet. Der Artikel beschreibt, mit welchen Mitteln man in OpenOffice.org Calc Urlisten auszählen kann, um eine Häufigkeitsverteilung zu erstellen.

Wenige Merkmalsausprägungen

A

B

1

Wurf

2

5

3

3

4

6

Mit ZÄHLENWENN

Zur Auswertung legen Sie nun eine Tabelle dieser Form an:

A

B

C

D

E

1

Wurf

Zahl

Anzahl

relative Häufigkeit

2

5

1

3

3

2

4

6

3

In der Spalte C tragen Sie ab Zelle C2 die Merkmalsausprägungen ein, hier also die Zahlen 1 bis 6. In der Zelle D2 tragen Sie diese Formel ein:

=ZÄHLENWENN($A$2:$A$31;C2)

Dies ermittelt wie oft der in der Zelle C2 stehende Wert in dem Bereich $A$2:$A$31 vorkommt. Die absolute Adressierung in der Bereichsadresse ist erforderlich, damit Sie die Formel nach unten kopieren können, ohne dass sich die Referenz ändert. Sie können natürlich den Bereich vorher z.B mit „Wurfdaten“ benennen und hier dann den Bereichsnamen benutzen. Dann lautete die Formel

=ZÄHLENWENN(Wurfdaten;C2)

Diese Formel kopieren Sie nun in die Zellen D3 bis D7.

Für die relativen Häufigkeiten benutzen Sie die Regel „relative Häufigkeit = absolute Häufigkeit ÷ Anzahl der Werte“. In der Zelle E2 steht daher die Formel

=D2/30

Wenn Sie die Anzahl der Daten nicht selbst ermitteln wollen, benutzen Sie statt dessen

=D2/ANZAHL(Wurfdaten)

Auch hier kopieren Sie die Formel dann nach unten bis E7.

In der ersten Zeile können Sie passende Spaltenüberschriften hinzufügen.

Mit Datenpilot

Der DatenPilot kann Ihnen das Eintragen der Merkmalsausprägungen und das Benutzen von Formeln ersparen. So gehen Sie vor:

Sie erhalten beispielsweise

datenpilot.png

Um diese Häufigkeitstabelle zu entfernen, klicken Sie hinein und benutzen dann über Daten → Datenpilot oder aus dem KontextMenü den Eintrag Löschen.

Viele Merkmalsausprägungen

Einteilung in Klassen

Hat das Merkmal sehr viele Merkmalsausprägungen oder handelt es sich um ein stetiges Merkmal, werden Sie die Merkmalsausprägungen zu Klassen zusammenfassen und statt der Häufigkeit einer einzelnen Merkmalsausprägung die Klassenhäufigkeit betrachten.

In der Häufigkeitstabelle werden statt der Merkmalsausprägungen die Klassengrenzen eingetragen, beginnend mit der niedrigsten.

(!) Wählen Sie die Klassengrenzen so, dass die erste Klasse und die letzte keine Daten mehr enthält. Dann können Sie die erste und letzte Klasse als nach unten bzw. oben offen interpretieren und zur Kennzeichnung der restlichen Klassen jeweils die Klassenmitte benutzen.

Die Klassen brauchen nicht gleich breit zu sein. Besonders die äußeren Klassen, die in vielen Anwendungsfällen nur „Ausreißer“ enthalten, werden oft breiter gewählt.

Zum Auswertung legen Sie nun eine Tabelle dieser Form an:

A

B

C

D

E

1

Zeit
in s

Klasse

Anzahl

2

8,6

7,4

3

8,8

8,0

4

8,5

8,6

5

9,2

9,2

6

8,9

9,8

7

8,4

10,4

8

9,4

11,4

9

9,0

>11,4

10

9,8

In der Spalte D tragen Sie ab Zelle D2 die oberen Klassengrenzen ein.

Auszählen mit der Funktion HÄUFIGKEIT

Für das Auszählen stellt Ihnen OpenOffice.org die Funktion HÄUFIGKEIT zur Verfügung. Bei dieser Funktion gehört die obere Grenze der Einteilungsstufen jeweils zu der Klasse hinzu und die oberste Klasse ist in OpenOffice.org immer nach oben offen.

Die Funktion HÄUFIGKEIT ist eine Matrixfunktion. Sie finden sie daher nicht in der Kategorie Statistik sondern in der Kategorie Matrix. Beachten Sie die Hinweise in CalcFunktionenMatrix für den Umgang mit Matrixformeln. Denken Sie insbesondere daran, die Eingabe mit Umschalt+Strg+Enter abzuschließen.

Die Formel lautet in dem Beispiel:

{=HÄUFIGKEIT(A2:A71;D2:D9)}

Der erste Parameter der Funktion ist der auszuwertende Datenbereich, der zweite Parameter ist der Bereich, in dem die Klassengrenzen stehen. Bevor Sie die Formel eingeben, markieren Sie den gesamten Bereich neben der Klasseneinteilung, der die Ergebnisse aufnehmen soll, im Beispiel also E2:E9.

Sie erhalten dann

A

B

C

D

E

1

Zeit
in s

Klasse

Anzahl

2

8,6

7,4

0

3

8,8

8,0

3

4

8,5

8,6

16

5

9,2

9,2

28

6

8,9

9,8

14

7

8,4

10,4

7

8

9,4

11,4

2

9

9,0

>11,4

0

10

9,8

Auszählen mit Wahrheitswerten

Mit der Funktion ZÄHLENWENN können keine Abfragen der Form „Wert liegt zwischen“ durchgeführt werden. Als Ersatz kann die Funktion SUMME benutzt werden, Erklärungen und Beispiele dazu finden Sie in CalcFunktionenMatrix/RechnenWenn. In dem Beispiel hier schreiben Sie in die Zelle E2 die Matrixformel

{=SUMME($A$2:$A$71<D2)}

OpenOffice.org bildet nun eine interne, temporäre Spalte. Dort wird für jede Zeile des Bereichs $A$2:$A$71 der Wert WAHR oder FALSCH eingetragen, je nach dem ob der Vergleich <D2 zutrifft oder nicht. Da OpenOffice.org den Wahrheitswert WAHR arithmetisch wie eine „1“ behandelt und den Wahrheitswert FALSCH wie eine „0“, liefert die Summe über diesen temporären Bereich die Anzahl der zutreffenden Vergleiche.

In die Zelle E3 kommt dann die Matrixformel

{=SUMME(($A42:$A$71<D3)*($A$2:$A$71>=D2))}

Durch die Multiplikation wird eine UND-Verknüpfung realisiert, weil das Produkt nur dann von Null verschieden (WAHR) ist, wenn beide Faktoren ungleich Null sind.

Sie können diese Formel nicht durch Ziehen mit der Maus in die nächsten Zeilen kopieren, weil sich dadurch nur der Ergebnisbereich für die Matrixformel ändern würde. Statt dessen kopieren Sie die Formel mit Strg+c, markieren den Bereich E4:E8 und fügen die Formel dann mit Strg+v ein.

Zum Schluss kommt noch in die Zelle E9 die Formel

{=SUM($A$2:$A$71>=D8)}

Bei dieser Lösung sind Sie frei, zu welcher Klasse die Klassengrenze gehören soll. In dem Beispiel wurde sie der darüber liegenden Klasse zugeordnet, wodurch sich etwas andere Anzahlen ergeben als mit der Funktion HÄUFIGKEIT.

A

B

C

D

E

1

Zeit
in s

Klasse

Anzahl

2

8,6

7,4

0

3

8,8

8,0

2

4

8,5

8,6

14

5

9,2

9,2

26

6

8,9

9,8

17

7

8,4

10,4

8

8

9,4

11,4

3

9

9,0

>11,4

0

10

9,8

Auszählen mit ZÄHLENWENN

Zwar kann man bei der Funktion Zählenwenn keine Bedingung für „Wert liegt zwischen“ direkt angeben, aber eine solche Bedingung lässt sich mit Hilfe einer Subtraktion realisieren. Um die Bedingung 7,4<Wert<=8 zu realisieren schreiben Sie zum Beispiel

=ZÄHLENWENN($A$2:$A$71;"<=8")-ZÄHLENWENN($A$2:$A$71;"<=7,4")

In der Häufigkeitstabelle sollen die Grenzen aber nicht fest in die Formel eingetragen werden, sondern aus der daneben liegenden Spalte stammen. Statt "<=8" heißt es daher "<="&D3. Beachten Sie, dass die Bedingung ein Text sein muss und der Zellinhalt von D3 daher mit dem Textverknüpfungszeichen & an den Text "<=" angehängt wird.

Wenn die obere Klassengrenze wie bei der Funktion Häufigkeit mit zu der Klasse gehören soll, dann benötigen Sie die Formeln

in E2 : =ZÄHLENWENN($A$2:$A471;"<="&D2)

in E3 : =ZÄHLENWENN($A$2:$A$71;"<="&D3)-ZÄHLENWENN($A$2:$A$71;"<="&D2)

nach unten kopieren bis einschließlich E8

in E9 : =ZÄHLENWENN(A2:A71;D9) wobei die Zelle D9 den Bedingungstext enthält.

Klassenhäufigkeit mit Hilfsspalte auszählen

Auch mit dem DatenPilot können keine Einteilungen der Art „Wert liegt zwischen“ durchgeführt werden, sondern nur Einteilungen der Art „gehört zu dieser Rubrik“. Sie brauchen daher, wenn Sie den Datenpiloten benutzen wollen, eine Hilfsspalte, in der statt der eigentlichen Merkmalsausprägung die zugehörige Klasse steht.

Um diese Hilfsspalte von OpenOffice.org berechnen zu lassen, eignet sich die Funktion VERWEIS. Dazu erstellen Sie eine Tabelle für die Klasseneinteilung und definieren für jede Klasse eine Bezeichnung. Als Bezeichnung können Sie auch die Klassenmitten verwenden. Für letzteres schreiben Sie im Beispiel in die Zelle F2 die Formel

=(D2+D3)/2

um die Mitte zu berechnen und kopieren diese Formel dann bis F7 nach unten. Weil die erste und letzte Klasse so gewählt wurde, dass sie keine Elemente enthält, kann man hier die Klassenmitten tatsächlich berechnen, wenn man die erste und letzte Klasse weglässt.

A

B

C

D

E

F

1

Zeit
in s

Klasse

Klasse

Anzahl

Klassenbezeichnung

2

8,6

7,4

7,7

3

8,8

8,0

8,3

4

8,5

8,6

8,9

5

9,2

9,2

9,5

6

8,9

9,8

10,1

7

8,4

10,4

10,9

8

9,4

11,4

9

9,0

>11,4

10

9,8

In die Zelle B2 tragen Sie nun diese Formel ein:

=VERWEIS(A2;$D$2:$F$7;$F$2:$F$7)

Der erste Parameter enthält den Wert, zu dem Sie die Klassenbezeichnung ermitteln wollen.

Der zweite Parameter enthält die Liste, in der Sie suchen. Diese Liste muss aufsteigend sortiert sein. Alle Werte, die nicht genau einem Eintrag entsprechen, werden dem darunter liegendem Eintrag zugeordnet. Die Merkmalsausprägung 8,6 wird also der Klasse „8,9“ zugeordnet. Diese enthält daher alle Merkmalsausprägungen x mit 8,6 ≤ x < 9,2.

Mit dem dritten Parameter legen Sie die Ergebnisliste fest, die die Klassenbezeichnungen enthält.

Die absolute Adressierung bei den Listen ist erforderlich, damit Sie die Formel in die anderen Zellen der Spalte B kopieren können.

Nun wenden Sie wie oben unter „Wenige Merkmalsausprägungen“ beschrieben den Datenpiloten auf den Bereich B2:B71 an oder zählen den Bereich mit der Funktion ZÄHLENWENN aus.


KategorieCalc


LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28