Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

Da sich beim computing das Rechnen nicht mehr nur auf Zahlen beschränkt, bieten Tabellenkalkulationsprogramme wie Calc auch eine Fülle von Funktionen an, mit denen Text-Inhalte von Zellen bearbeitet werden können. Eine vollständige Liste der Funktionen, die dem Bereich Text zugeordnet werden, findet sich auf DeutschEnglischCalcFunktionen/Text oder im Programm-Hilfetext unter dem Stichwort Funktionen.

1. Textformate ↔ Zahlenformate

Editieren

1.1. Umwandlungen vom und ins Textformat

1.1.1. Zahlen ins Textformat wandeln

1.1.1.1. Führende Null bei PLZ

Nicht immer genügt es, die führende Null bei Postleitzahlen mit dem entsprechenden Zahlenformat zu erzwingen. Dann kann man die Zahl mit TEXT(Zahl;Format) in die richtige Darstellung bringen.

A

B

C

D

1

PLZ

Ort

Verkettung

Formel

2

4679

Irgendwo

4679 Irgendwo

=VERKETTEN(A2;" ";B2)

3

86473

Sonstwo

86473 Sonstwo

=VERKETTEN(A3;" ";B3)

4

60573

Nirgendwo

60573 Nirgendwo

=VERKETTEN(A4;" ";B4)

5

5642

Überall

5642 Überall

=VERKETTEN(A5;" ";B5))

6

7

4679

Irgendwo

04679 Irgendwo

=VERKETTEN(TEXT(A7;"00000");" ";B7)

8

86473

Sonstwo

86473 Sonstwo

=VERKETTEN(TEXT(A8;"00000");" ";B8)

9

60573

Nirgendwo

60573 Nirgendwo

=VERKETTEN(TEXT(A9;"00000");" ";B9)

10

5642

Überall

05642 Überall

==VERKETTEN(TEXT(A10;"00000");" ";B10)

1.1.1.2. Kalender- und Zeitdaten als und in Zeichenketten darstellen

A

B

C

1

Zahl im Datum/Zeit-Format

Formel

2

28.08.05 17:30

17

=STUNDE(A2)

3

nachmittags

=WENN(B2<=12;"vormittags";"nachmittags")

4

Sonntag, 28. August 2005

=TEXT(A2;"NNNNT. MMMM JJJJ")

5

17:30

=TEXT(STUNDE(A2);"00")&":"&TEXT(MINUTE(A2);"00")

7

Wir treffen uns am Sonntag, 28. August 2005 um 17:30 nachmittags
Formel: =VERKETTEN("Wir treffen uns am "; TEXT(A2;"NNNNT. MMMM JJJJ");" um  "; TEXT(STUNDE(A2);"00")&":"&TEXT(MINUTE(A2);"00"); " ";WENN(STUNDE(A2)<=12;"vormittags";"nachmittags"))

1.1.1.3. Weitere Textformate für Zahlenwerte

Im Parameter: Format der Funktion TEXT() können die gleichen Schreibweisen benutzt werden, wie sie im Zellformat → Register: Zahlen zur Verfügung stehen:

A

B

C

1

Zahl

Zeichenkette

Formel

3

0,075

7,50 %

=TEXT(A3;"0,00 %")

4

2,75

2 3/4

=TEXT(A4;"# ?/?")

2

12,35

12,35 €

=TEXT(A2;"#.##0,00 [$€-407];[ROT]-#.##0,00 [$€-407]")

1.1.1.4. Funktion DM() für Währungsformate

Mit der Funktion DM() wird eine Zahl mit demjenigen Währungszeichen dargestellt, welches unter Extras → Optionen → Spracheinstellungen → Sprachen als Standardwährung eingestellt ist. Das Ergebnis ist auch ein Textformat, mit dem nicht gerechnet werden kann.

A

B

C

1

12,35

12,35 €

=DM(A1;2)

1.1.1.5. Funktion FEST() für eine feste Anzahl Nachkommastellen

Mit der Funktion Fest() wird eine Zahl in ein Textformat überführt mit einer fest definierten Anzahl Nachkommastellen. Optional kann bestimmt werden, ob ein Tausendertrennzeichen verwendet werden soll.

A

B

C

1

8123

8123,0000

=FEST(A1;4;1)

2

8123

8.123,0000

=FEST(A2;4;0)

1.1.2. Zahl aus einer Zeichenkette herausfiltern

1.1.2.1. Wenn die Position und Länge der Ziffer bekannt ist

Aus der Zeichenkette 28 Äpfel soll die Zahl herausgefiltert und im Zahlenformat zur Verfügung gestellt werden, um damit rechnen zu können. Dazu wird zunächst nach der Position des Leerzeichens gesucht, anschliessend die Zeichen vom Anfang der Zelle bis zum Leerzeichen herausgeschnitten und die so erhaltene Zeichenfolge in eine Zahl umgewandelt.

A

B

C

1

28 Äpfel

28

=WERT(TEIL(A1;1;FINDEN(" ";A1)-1))

Das Ganze kann man auch mit einer Prüfung verbinden, die abklärt, ob es sich bei der gefundenen Zeichenkette überhaupt um eine Zahl handelt:

A

B

C

1

Zeichenkette

Anzahl mal 5

Formel

2

28 Äpfel

140

=WERT(TEIL(A2;1;FINDEN(" ";A2)-1))*5

3

achtundzwanzig Äpfel

Hey, ich brauche Zahlen zum Rechnen!

WENN(ISTZAHL(WERT(TEIL(A3;1;FINDEN(" ";A3)-1))); WERT(TEIL(A3;1;FINDEN(" ";32)-1))*5; "Hey, ich brauche Zahlen zum Rechnen!")

1.1.2.2. Wenn weder Position noch Anzahl der Ziffern bekannt ist

Mit den Funktionen FINDEN() oder SUCHEN() kann man zwar einen Text auf das Vorkommen einer bestimmten Zeichenfolge untersuchen, aber man muss ein genaues Zeichenmuster mitgeben können. Reguläre Ausdrücke im Sinn von ^[0-9] sind nicht möglich.

Trotzdem kann man reguläre Ausdrücke heranziehen, um das Problem zu lösen:
Im folgenden Beispiel wird allen Ziffern, die nach einem Leerzeichen stehen, mit Hilfe von Bearbeiten → Suchen&Ersetzen ein Zeichen vorangestellt, das sonst nicht vorkommt, im Beispiel ist das #. Damit haben wir ein eindeutiges Zeichen, mit dem wir die Startposition der Ziffern lokalisieren können. In einem zweiten Suchen/Ersetzen-Durchlauf werden alle Ziffern, die vor einem Leerzeichen stehen, ergänzt um das Zeichen *, womit auch das Ende der Ziffer klar ist.

Texte vor dem Aufruf von Suchen/Ersetzen:

A

1

Heute haben wir 47 Äpfel verkauft.

2

Gestern haben wir 113 Äpfel verkauft.

3

Vorgestern haben wir 9 Äpfel verkauft.

1.1.2.2.1. Menu: Bearbeiten -> Suchen&Ersetzen

Der erste Suchaufruf wird mit diesen Einstellungen gestartet:

Das Feld Suchen nach beginnt mit einem Leerzeichen.

SuchenErsetzen1.png

Der zweite Suchaufruf wird mit diesen Einstellungen gestartet:

Das Feld Suchen nach endet mit einem Leerzeichen.

SuchenErsetzen2.png

Texte nach dem Aufruf von Suchen/Ersetzen:

A

Alle Ziffern beginnen 2 Stellen nach # und enden 2 Stellen vor *, die Ziffernlänge ergibt sich aus der Differenz zwischen den Fundstellen und nach Abzug des Leerzeichens.

1

Heute haben wir# 47 *Äpfel verkauft.

2

Gestern haben wir# 113 *Äpfel verkauft.

3

Vorgestern haben wir# 9 *Äpfel verkauft.

A

B

C

1

Heute haben wir# 47 *Äpfel verkauft.

47

=WERT(TEIL(A1;SUCHEN("#";A1)+2;SUCHEN("*";A1)-SUCHEN("#";A1)-3))

2

Gestern haben wir# 113 *Äpfel verkauft.

113

=WERT(TEIL(A2;SUCHEN("#";A2)+2;SUCHEN("*";A2)-SUCHEN("#";A2)-3))

3

Vorgestern haben wir# 9 *Äpfel verkauft.

9

=WERT(TEIL(A3;SUCHEN("#";A3)+2;SUCHEN("*";A3)-SUCHEN("#";A3)-3))

Wenn die Original-Zeichenkette ebenfalls zur Verfügung stehen soll, kann in einer Zusatzspalte der Text wieder von die Markierungszeichen befreit werden:

A

B

C

1

Heute haben wir# 47 *Äpfel verkauft.

Heute haben wir 47 Äpfel verkauft.

=WECHSELN(WECHSELN(A1;"# ";" ");" *";" ")

2

Gestern haben wir# 113 *Äpfel verkauft.

Gestern haben wir 113 Äpfel verkauft.

=WECHSELN(WECHSELN(A2;"# ";" ");" *";" ")

3

Vorgestern haben wir# 9 *Äpfel verkauft.

Vorgestern haben wir 9 Äpfel verkauft.

=WECHSELN(WECHSELN(A3;"# ";" ");" *";" ")

1.1.3. Die Funktionen T() und N()

Mit der Funktion T() wird ein Zahlenwert in einen leeren Textstring verwandelt, wohingegen eine Zahl, die als Text formatiert ist, nicht verändert wird.

Mit der Funktion N() wird ein Wert in eine Zahl mit dem Wert 0 verwandelt, wohingegen eine Zahl, die auch als solche formatiert ist, nicht verändert wird.

A

B

C

D

E

In Zelle A1 steht die Zahl im Zahlenformat, in Zelle A2 im Zeichenformat (mit Hochkomma vor der Zahl)

1

    12345

=T(A1)

12345

=N(A1)

2

12345    

12345

=T(A2)

0

=N(A2)

Die Funktion T() wird auch im Zusammenhang mit Vorlagenzuweisungen benötigt.
Siehe auch: show

1.1.4. Zellen mit unterschiedlichem Format vergleichen

Wenn in zwei Zellen die gleiche Zahl steht, aber eine dieser Zellen als Text formatiert ist, während die andere ein Zahlenformat darstellt, so ergibt eine Abfrage mit WENN(A1=A2) FALSCH.

Mit der Funktion IDENTISCH() kann man die Berücksichtigung des Formates unterbinden:

A

B

C

Die linksbündige Zahl liegt jeweils im Textformat vor, während die rechtsbündige Zahl ein Zahlenformat darstellt.

1

     23

FALSCH

=WENN(A1=A2)

2

23     

3

4

     23

WAHR

=IDENTISCH(A4;A5)

5

23     

1.2. Römische, arabische Ziffern

1.2.1. Römische Ziffern

Bei der Darstellung von Zahlen als römische Ziffern gibt es bei einigen Ziffernkombinationen mehrere Schreibweisen. Diesem Umstand trägt die Funktion mit dem Modus Rechnung.

A

B

C

D

1

999

CMXCIX

=RÖMISCH(A1)

=(1000-100)+(100-10)+(10-1)

2

LMVLIV

=RÖMISCH(A1;1)

=(1000-50)+(50-5)+(5-1)

3

XMIX

=RÖMISCH(A1;2)

=(1000-10)+(10-1)

4

VMIV

=RÖMISCH(A1;3)

=(1000-50)+(50-1)

5

IM

=RÖMISCH(A1;4)

=1000-1

Die reine Additionsvariante wird von Calc nicht angeboten, es versteht sie aber und kann sie mit der Funktion ARABISCH() (s. u.) umsetzen.

1.2.2. Arabische Ziffern

A

B

C

1

CMXCIX

999

=ARABISCH(A1)

2

999

=ARABISCH("DCCCCLXXXXVIIII")

KategorieCalc

2. Zeichenketten manipulieren

Editieren

2.1. Zellen aufteilen

Bei Adresstabellen, die z.B. für Serienbriefe verwendet werden sollen, kommt es häufig vor, dass der Inhalt einer Tabellenspalte auf mehrere Spalten verteilt werden muss. Wenn die Spaltenaufteilung eindeutig ist, gibt es verschiedene Möglichkeiten, dies zu bewerkstelligen. Die Funktionen LINKS(), RECHTS() und TEIL() können meist alternativ genutzt werden.

In jedem Fall benötigt man Angaben über die Länge der Texteile, die herausgefiltert werden soll. Die Funktionen SUCHEN() und FINDEN() können nach einem Trennzeichen suchen und geben die Position der Fundstelle an. Soll z.B. alles bis zum ersten Leerzeichen aus einer Zeichenkette herausgefiltert werden, so fängt der herauszufilternde Teil auf Position 1 an und geht bis eine Stelle vor dem Leerzeichen. Benötigt man einen Teil der Zeichenkette, der irgendwo anfängt und bis zum Ende des Ausgangstextes gehen soll, so lokalisiert man wieder die Startposition mit SUCHEN() oder FINDEN() und benutzt LÄNGE() für die Anweisung bis zum Ende.

2.1.1. Aus eins mach zwei

Wenn der Text einer Zelle in einen linken und einen rechten Teil aufgetrennt werden soll, eignen sich dafür die Funktionen LINKS() und RECHTS():

A

B

C

D

1

Aufzuteilende Zeichenkette

Teilstring

Formel

2

01234/567891

Vorwahl:

01234

=LINKS(A2;SUCHEN("/";A2)-1)

3

Anschluss:

567891

=RECHTS(A2;LÄNGE(A2)-SUCHEN("/";A2))

4

Anschluss:

56'78'91

=VERKETTEN(TEIL(RECHTS(A2;LÄNGE(A2)-SUCHEN("/";A2)) ;1;2);"'";TEIL(RECHTS(A2;LÄNGE(A2)-SUCHEN("/";A2));3;2);"'"; TEIL(RECHTS(A2;LÄNGE(A2)-SUCHEN("/";A2));5;2))

2.1.2. Mehrfachaufteilung

Im folgenden Beispiel muss zweimal nach einem Leerzeichen gesucht werden. Für das zweite Vorkommen muss daher der Such-Startpunkt nach dem Erst-Vorkommen liegen.

A

B

C

D

1

Aufzuteilende Zeichenkette

Teilstring

Formel

2

Herr Felix Muster

Anrede:

Herr

=TEIL(A2;1;SUCHEN(" ";A2)-1)

3

Vorname:

Felix

=TEIL(A2;SUCHEN(" ";A2)+1;SUCHEN(" ";A2; SUCHEN(" ";A2)+1)-(SUCHEN(" ";A2)+1))

4

Nachname:

Muster

=TEIL(A2;SUCHEN(" ";A2;SUCHEN(" ";A2)+1)+1;LÄNGE(A2))

2.2. Inhalte mehrerer Zellen zusammenführen

Beim Zusammenführen mehrerer Zellen darf nicht vergessen werden, bei Bedarf Trennzeichen wie z.B. Leerzeichen zwischen die Inhalte der einzelnen Zellen einzufügen.

A

B

C

1

Länder-Kennzeichen:

D

Formel

2

Postleitzahl:

28195

3

Ort:

Bremen

4

D28195Bremen

=VERKETTEN(B1;B2;B3)

5

D-28195 Bremen

=VERKETTEN(B1;"-";B2;" ";B3)

6

D-28195 Bremen

=B1&"-"&B2&" "&B3

2.2.1. Eine Zeichenkette wiederholen

A

B

C

1

Edeltraut

''oh jeh, oh jeh, oh jeh, '' jammerte Edeltraut.

=VERKETTEN("''";WIEDERHOLEN("oh jeh, ";3);"'' jammerte ";A20;".")

2.2.2. Einen Zeilenumbruch einfügen

(./) OOo 3.2

Beim Verketten von Zellen in Calc-Dokumenten kann es vorkommen, daß zwischen den zusammengeführten Zeichenketten in der Ergebniszelle ein Zeilenumbruch erfolgen soll.

Dazu kann mit Hilfe der Funktion ZEICHEN() das ANSI-Zeichen für einen Zeilenumbruch eingefügt werden: ZEICHEN(10). Die ganze Formel könnte also so aussehen: =A1&ZEICHEN(10)&B1 bzw. =VERKETTEN(A1;ZEICHEN(10);B1).

Beispiel:

A

B

C

1

Briefmarke

Meist rechteckiges, oftmals gezähntes Postwertzeichen, das auf Papier gedruckt wird und zur Bezahlung der Beförderung von Postsendungen dient

Briefmarke:
Meist rechteckiges, oftmals gezähntes Postwertzeichen, das auf Papier gedruckt wird und zur Bezahlung der Beförderung von Postsendungen dient

Formel in C1: =A1&":"&ZEICHEN(10)&B1


KategorieTipps KategorieCalc

2.3. Einem Zellinhalt eine Zellvorlage hinzufügen

Eine Zellvorlage kann man ganz einfach zu einem Zellinhalt hinzuaddieren. Man muss jedoch unterscheiden, ob der Inhalt der Zelle numerisch oder alfanumerisch ist. Wenn es sich um einen alfanumerischen Wert handelt, muss die Vorlagenzuweisung mit der Funktion T() kombiniert und mit & statt + angehängt werden.

A

B

C

1

123

123

=A1+VORLAGE("RoterHintergrund")

2

Text

0

=A2+VORLAGE("RoterHintergrund")

3

Text

Text0

A3&VORLAGE("RoterHintergrund")

4

Text

Text

A4&T(VORLAGE("RoterHintergrund"))

5

Text

Text

=VERKETTEN(A5;T(VORLAGE("RoterHintergrund")))

2.4. Einen Text SUCHEN() oder FINDEN()?

Diese beiden Funktionen suchen in einem Text eine Zeichenkette und geben beim Auffinden die Position zurück, an welcher das gesuchte Zeichen steht oder die gesuchte Zeichenkette beginnt. FINDEN() unterscheidet dabei zwischen Gross- und Kleinschreibung, während SUCHEN() dies ignoriert.

A

B

C

1

Es ist, wie es ist, sprach die Liebe

#WERT!

=FINDEN("liebe";A1)

2

32

=FINDEN("Liebe";A1)

3

32

=SUCHEN("liebe";A1)

Wenn man mehrere Vorkommen eines Zeichens finden will, muss man mehrere Suchfunktionen verschachteln und jeweils die Start-Position so versetzen, dass eine Folgesuche erst nach der Position des letzten Vorkommens beginnt.

A

B

C

1

Es ist, wie es ist, sprach die Liebe

2

Erstes Leerzeichen auf Position:

3

=SUCHEN(" ";A1)

3

Zweites Leerzeichen auf Position:

8

=SUCHEN(" ";A1;SUCHEN(" ";A1)+1)

4

Drittes Leerzeichen auf Position:

12

=SUCHEN(" ";A1;SUCHEN(" ";A1;SUCHEN(" ";A1)+1)+1)

2.5. Einen Text WECHSELN() oder ERSETZEN()?

In Tabellen, bei denen strukturierte Textdateien eingelesen werden, kommt es oft vor, dass an Textstellen, die nicht durch ihren Inhalt, sondern durch ihre Position bestimmt werden, eine Zeichenkette ausgetauscht werden soll. Dafür eignet sich die Funktion ERSETZTEN().

A

B

C

1

Das Treffen fand am 060805 statt.

Das Treffen fand am 06.08.05 statt.

=ERSETZEN(A1;21;6;VERKETTEN(TEIL(A1;21;2);"."; TEIL(A1;23;2);".";TEIL(A1;25;2)))

Die Funktion WECHSELN() benötigt keine Positions- und Längenangaben. Sie sucht eine vorgegebene Zeichenkette und ersetzt sie durch eine andere. Dabei können alle Vorkommen ausgetauscht werden oder nur einzelne.

A

B

C

1

imer wieder der gleiche Fehler mit dem imer!

immer wieder der gleiche Fehler mit dem immer!

=WECHSELN(A1;"imer";"immer")

2

immer wieder der gleiche Fehler mit dem imer!

=WECHSELN(A1;"imer";"immer";1)

3

imer wieder der gleiche Fehler mit dem immer!

=WECHSELN(A1;"imer";"immer";2)

Sowohl bei ERSETZEN() wie auch bei WECHSELN() müssen die zu ersetzende und die neue Zeichenkette nicht gleich lang sein. Die Gesamtlänge wird bei Bedarf angepasst, sodass weder Zeichen verlorengehen noch Lücken entstehen können.

2.5.1. Verschachtelte WECHSELN-Anweisungen

Was man mit dem Suchen&Ersetzen-Modul mit mehreren Durchläufen bewerkstelligt, kann man mit der WECHSELN()-Funktion durch Verschachtelung erreichen. Im nachstehenden Beispiel sollen alle Umlaute entfernt werden, also ä durch ae, ö durch oe und ü durch ue ersetzt werden:

A

B

C

1

Jörg aus Österreich hänselt die Übrigen zum Ärger des wütenden Lehrers.

Joerg aus Oesterreich haenselt die Uebrigen zum Aerger des wuetenden Lehrers.

=WECHSELN(
  WECHSELN(
    WECHSELN(
      WECHSELN(
        WECHSELN(
          WECHSELN(A1;"ä";"ae");
          "ü";"ue");
        "ö";"oe");
      "Ü";"Ue");
    "Ö";"Oe");
"Ä";"Ae")

(!) Tipp für das Vorgehen:

  1. Man beginnt mit der ersten Wechsel-Anweisung: =WECHSELN(A1;"ä";"ae")

  2. Man positioniert den Cursor in der Eingabezeile und schneidet alles nach dem =-Zeichen aus (CTRL+X).

  3. Man ruft den FunktionsAutopiloten auf, wählt die Funktion WECHSELN(), setzt ins Feld Text die eben ausgeschnittene Formel ein (CTRL+V), ergänzt die Felder Suchtext und Textersatz mit dem nächsten Auswechsel-Paar und schliesst die Autopilot-Eingabe ab.

  4. Man wiederholt ab Punkt 2 so oft, bis alle Auswechslungen definiert sind.

2.6. Tipp

Leider kann man nicht den Inhalt mehrere Zellen mit einem Befehl wie etwa =VERKETTEN(A1:Z1) aneinanderhängen, sondern muss jede Zelle aufzählen: =VERKETTEN(A1;B1;C1;...;Z1).

Je nach Situation kann folgendes Vorgehen helfen:

  • Die ganzen Spalten markieren und kopieren
  • Der Cursor wird in eine leere Spalte setzen
  • Das Einfüge-Icon aufklappen (mit dem kleinen Pfeil daneben) und die Option unformatierter Text wählen

  • Im folgenden Fenster die Trennoption Getrennt wählen, aber alle Selektionsboxen deaktivieren.

Ergebnis: Die Inhalte aller Spalten werden ohne Trennzeichen in eine Spalte zusammengezogen.

Wenn man Trennzeichen zwischen den Zellen der einzelnen Spalten benötigt, kann man das so bewerkstelligen:

  • Die Spalten, deren Zellen pro Zeile zusammengezogen werden sollen, markieren
  • Aufrufen: Bearbeiten → Suchen & Ersetzen (Alternativ: STRG+S), Einstellungen:
    Suchen nach: .*\>
    Ersetzen durch: &#
    Optionen: Regulärer Ausdruck und nur in Selektion
    Drücken: Ersetze alle

  • Damit wird an den Inhalt jeder Zelle ein # angehängt (kann auch ein anderes Zeichen sein, jedenfalls eins, dass sonst nicht vorkommt)
  • Die so behandelten Spalten in die Zwischenablage kopieren, mit CTRL+Z das Anfügen des Zusatzzeichens in den Originalspalten wieder rückgängig machen und den Inhalt der Zwischenablage wie oben beschrieben in eine neue Spalte einfügen.

  • Allenfalls mit SuchenUndErsetzen das Spezialzeichen durch das endgültige Trennzeichen austauschen

3. Die Darstellung von Zeichenketten ändern

Editieren

3.1. Gross- und Kleinschreibung

Die Funktionen für Gross- und Kleinschreibung haben nichts mit der Rechtschreibung zu tun. Sie bereiten einen Text nicht nach logischen Gesichtspunkten auf, sondern nach einfachen Regeln: alle Buchstaben (GROSS() bzw. KLEIN()), immer der erste Buchstabe jedes Wortes (GROSS2()).

A

B

1

BERLIN SCHÖNEFELD

2

=KLEIN(B1) 

berlin schönefeld

3

=GROSS2(KLEIN(B1)) 

Berlin Schönefeld

4

=GROSS(B2) 

BERLIN SCHÖNEFELD

3.2. ROT13-Verschlüsselung

Eine ROT13-Veschlüsselung kann helfen, dass ein Text nicht versehentlich gelesen wird. Aber von einem eigentlichen Verschlüsselungs-Algoritmus kann nicht die Rede sein. Es werden nur die Buchstaben des Alfabetes verschoben und es gibt eine Reihe von Programmen, welche diese Verschlüsselung wieder rückgängig machen können.

In Calc wird ein mit ROT() verschlüsselter Text mit der gleichen Funktion wieder lesbar gemacht:

A

B

1

Ein US-Geheimdienst kann mit einem weltweiten elektronischen Überwachungssystem jedes Telefongespräch, jede EMail oder Telex-Kommunikation abhorchen. Was bislang nur als Gerücht kursierte, wurde von einer Kommission des europäischen Parlaments bestätigt, berichtete der Londoner Telegraph.

2

=ROT13(B1) 

Rva HF-Trurvzqvrafg xnaa zvg rvarz jrygjrvgra ryrxgebavfpura Üorejnpuhatfflfgrz wrqrf Gryrsbatrfceäpu, wrqr RZnvy bqre Gryrk-Xbzzhavxngvba noubepura. Jnf ovfynat ahe nyf Treüpug xhefvregr, jheqr iba rvare Xbzzvffvba qrf rhebcävfpura Cneynzragf orfgägvtg, orevpugrgr qre Ybaqbare Gryrtencu.

3

=ROT13(B2) 

Ein US-Geheimdienst kann mit einem weltweiten elektronischen Überwachungssystem jedes Telefongespräch, jede EMail oder Telex-Kommunikation abhorchen. Was bislang nur als Gerücht kursierte, wurde von einer Kommission des europäischen Parlaments bestätigt, berichtete der Londoner Telegraph.

3.3. Text von nicht druckbarem Ballast befreien

Wenn Daten importiert werden, kann es immer vorkommen, dass irgendwelcher "Zeichenmüll" in einer Tabelle landet. Mit der Funktion SÄUBERN() können diese Zeichen entfernt werden:

A

B

1

Saeubern.png

2

In diesem Text sind nicht druckbare Zeichen enthalten

=SÄUBERN(A1)

3.4. Überflüssige Leerzeichen

Überflüssige Leerzeichen kann man bekannterweise mit dem Aufruf Suchen/Ersetzen entfernen. Den muss man aber unter Umständen mehrmals laufen lassen, wenn die Anzahl der Leerzeichen unterschiedlich ist. Ausserdem werden auf die Art die Original-Zeichenketten verändert und man kann den Ausgangszustand nicht wieder herstellen.

Mit der Funktion GLÄTTEN() kann man das eleganter beheben:

A

B

1

In  diesem    Text    befinden sich       unnötige  Leerzeichen,   an    manchen     Stellen     mehr,      an   anderen      weniger.

Formel:

2

In diesem Text befinden sich unnötige Leerzeichen, an manchen Stellen mehr, an anderen weniger.

=GLÄTTEN(A1)

3.5. ASCII-Zeichensatz

Eine Zeichendarstellung vom oder in den ASCI-Code ist mit den Funktionen ZEICHEN() und CODE() möglich:

A

B

C

D

E

1

Formel in Spalte B

Formel in Spalte D

2

33

!

ZEICHEN(A2)

33

CODE(B2)

3

34

#

ZEICHEN(A3)

34

CODE(B3)

4

35

$

ZEICHEN(A4)

35

CODE(B4)

(!) Mit der Funktion ZEICHEN() kann man in einer Verketten-Formel auch einen Zeilenumbruch einfügen.

3.6. Hinweis

Wenn die Zeichenketten nach der Veränderung durch Calc-Funktionen unabhängig von der Formel gespeichert werden sollen, kann man die Formel-Ergebniszellen kopieren, den Einfügebildschirm über Bearbeiten → Inhalte einfügen aufrufen, dort die Option Formeln deaktivieren, Zeichenketten aber ausgewählt lassen.

KategorieCalc

4. siehe auch

CalcFunktionen WörterInZellenZählen


KategorieCalc


LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28