Archiv des LibreOffice- und OpenOffice.org-Wiki

[ÜberSicht] [TitelIndex] [WortIndex] [SeiteFinden

Editieren

Zeitwerte rechnen (wie Datumswerte) in ganzen Tagen. Das wird offensichtlich, wenn man einen Zeitwert durch 1 dividiert (A1 sei 12:00 und B2=A1/1, das Resultat ist 0,5)

1. Stunden addieren und in Dezimalzahlen umrechnen

Wenn Zeitwerte z.B. mit einem Stundenansatz multipliziert werden sollen, werden sie als Dezimalwert benötigt.

Aus einem Zeitwert wird durch die Multiplikation mit 24 ein dezimaler Stundenbetrag.
Aus einem Zeitwert wird durch die Multiplikation mit 24*60 ein dezimaler Minutenbetrag.
Aus einem Zeitwert wird durch die Multiplikation mit 24*60*60 ein dezimaler Sekundenbetrag.

A

B

C

D

E

F

G

H

1

Start

Ende

Start

Ende

Stunden
und
Minuten

Stunden
dezimal

Stunden
dezimal
gerundet

Stunden
dezimal
aufgerundet

2

07:00

11:20

13:30

17:00

07:50

7,84

7,75

8,00

3

4

07:00

11:20

13:30

17:00

07:50

Hinweis:
Übersteigt eine Berechnung ganze Tage, so wird je nach Formatierung unter Umständen nur der verbleibende Rest in Stunden angezeigt.
(Dezimalwerte werden aber stets vollständig angezeigt)

5

07:00

11:20

13:30

17:00

07:50

6

07:00

11:20

13:30

17:00

07:50

7

07:00

11:20

13:30

17:00

07:50

8

Summe: 

31:20

Format: [HH]:MM

9

Summe: 

07:20

Format: HH:MM

Zelle E2

Formel: =B2-A2+D2-C2
Format: HH:MM

Zelle F2

Formel: =(B2-A2+D2-C2)*24
Format: 0,00

Zelle G2

Formel: =VRUNDEN((B2-A2+D2-C2)*24;0,25)
Format: 0,00

Zelle H2

Formel: =OBERGRENZE((B2-A2+D2-C2)*24;0,25)
Format: 0,00

2. Minuten und Sekunden, Differenz im Zeit- oder Dezimalformat

Im vorigen Beispiel wurden Stunden durch die Multiplikation mit 24 in einen Dezimalwert umgerechnet. Bei Minuten muss zusätzlich mit 60 multipliziert werden. Im folgenden wird die Differenz zwischen zwei Zeiten errechnet und sowohl im Zeit- wie auch Dezimalformat ausgegeben, um z.B. Telefonkosten abzurechnen.

Bitte auch hier den Unterschied zwischen dem Format [HH]:MM:SS und HH:MM:SS bedenken (vgl. oben).

A

B

C

D

E

F

1

Start

Ende

Differenz im Zeitformat

Ganze Minuten

Sekunden

Differenz im Dezimalformat

2

12:41:10

12:45:50

00:04:40

4

40

4,67

Zellen A2/B2

Format: HH:MM:SS

Zelle C2

Formel: =B1-A1

Zelle D2

Formel: =GANZZAHL(B2*24*60-A2*24*60)

Zelle E2

Formel: =(B2-A2)*24*60*60-GANZZAHL((B2-A2)*24*60)*60

Zelle F2

Formel: =(B2-A2)*60*24

3. JAHR(), MONAT(), TAG(), STUNDE(), MINUTE(), SEKUNDE()

Mit diesen Funktionen kann man aus einem Datums- und/oder Zeitwert die gewünschten Details herausfiltern.

=JAHR(HEUTE())

ergibt beispielsweise die zum aktuellen Datum passende Jahreszahl vierstellig aus.

=MINUTE(JETZT())

ergibt die Minuten der aktuellen Uhrzeit.

/!\ ACHTUNG: Diese Funktionen liefern nicht die tatsächliche Anzahl z.B. von Stunden.

Beispiel: Aus einer Zeitspalte wird die Summe gebildet und ergibt 24:44:00, also 24 Stunden und 44 Minuten. Wenn man auf diesen Wert die Funktion STUNDE() anwendet, so ergibt sich:

=STUNDE(24:44:00) -> Ergebnis: 0

STUNDE() wird als Zahl zwischen 0 und 23 wiedergegeben. Ab 24 Stunden wird wieder bei 0 angefangen. Die tatsächliche Anzahl an Stunden muss man also anders berechnen, wie z.B.:

=GANZZAHL(24:44:00*24)
bzw.
=GANZZAHL(ZelleMitZeitwert*24)

4. Stunden und Tage, arbeiten mit verschiedenen Formaten

A

B

C

D

E

F

G

1

Start

Ende

Stunden und
Minuten

Stunden
dezimal

Tage

2

12.07.05 13:30

14.07.05 17:10

51:40

03:40

51,67

2,15

2,15

Zellen A2/B2

Format: TT.MM.JJ HH:MM

Zelle C2

Formel: =B2-A2
Format: [HH]:MM

Zelle D2

Formel: =B2-A2
Format: HH:MM

Zelle E2

Formel: =(B2-A2)*24
Format: 0,00

Zelle F2

Formel: =TAGE(B2-A2)
Format: 0,00

Zelle G2

Formel: =B2-A2
Format: 0,00

5. Stunden, Tage, Minuten getrennt

A

B

C

D

E

1

Start

Ende

Ganze Tage

Rest ganze Stunden

Rest Minuten

2

12.07.05 13:30

14.07.05 17:10

2

3

40

Zellen A2/B2

Format: TT.MM.JJ HH:MM

Zelle C2

Formel: =GANZZAHL(B2-A2)
Format: 0

Zelle D2

Formel: =GANZZAHL((B2-A2)*24)-GANZZAHL(B2-A2)*24
Format: 0

Zelle E2

Formel: =(B2-A2)*24*60-GANZZAHL((B2-A2)*24)*60
Format: 0

6. Datum und Zeit aus verschiedenen Zellen

A

B

C

D

E

F

G

H

I

J

1

Start-
Datum

Start-
Zeit

Schluss-
Datum

Schluss
Zeit

Tage

Stunden

Minuten

Ganze Tage

Rest ganze Stunden

Rest Minuten

2

01.08.2005

08:10

07.08.2005

15:40

6,31

151,50

9090

6

7

30

Zellen A2/C2

Format: TT.MM.JJJJ

Zellen B2/D2

Format: HH:MM

Zelle E2

Formel: =(C2+D2)-(A2+B2)
Format: 0,00

Zelle F2

Formel: =((C2+D2)-(A2+B2))*24
Format: 0,00

Zelle G2

Formel: =((C2+D2)-(A2+B2))*24*60
Format: 0,00

Zelle H2

Formel: =GANZZAHL((C2+D2)-(A2+B2))
Format: 0

Zelle I2

Formel: =GANZZAHL(((C2+D2)-(A2+B2))*24)-GANZZAHL((C2+D2)-(A2+B2))*24
Format: 0

Erklärung:
Es wird die Ganzzahl von Stunden ermittelt und davon die mit 24 multiplizierte Ganzzahl Tage subtrahiert

Zelle J2

Formel: =((C2+D2)-(A2+B2))*24*60-GANZZAHL(((C2+D2)-(A2+B2))*24)*60
Format: 0

Erklärung:
Es wird die Gesamtzahl Minuten ermittelt und davon die mit 60 multiplizierte Ganzzahl Stunden subtrahiert

7. Anzahl Tage zwischen zwei Datumsangaben

A

B

C

D

F

1

Von

Bis

Anzahl Tage
zwischen Von und Bis

2

01.01.2002

15.03.2007

1899

Formel in C2:

B2-A2

3

 

 

1899

Formel in C3:

=TAGE(B2;A2)

4

 

 

1874

Formel in C4:

=TAGE360(A2;B2;0)

Für die Zinsberechnung geht man üblicherweise von 360 Tagen pro Jahr aus.

0: US-Methode (NASD)

5

 

 

1874

Formel in C5:

=TAGE360(A2;B2;1)

1: europäische Methode (NASD)

8. Anzahl Monate zwischen zwei Datumsangaben

A

B

C

D

F

1

Von

Bis

Anzahl Monate
zwischen Von und Bis

2

29.02.2012

28.02.2013

11

Formel in C2:

=MONATE(A2;B2;0)

0: Intervall

3

29.02.2012

28.02.2013

12

Formel in C3:

=MONATE(A2;B2;1)

1: in Kalendermonaten

9. Anzahl Jahre zwischen zwei Datumsangaben

A

B

C

D

F

1

Von

Bis

Anzahl Jahre
zwischen Von und Bis

2

01.02.01

15.01.05

4

Formel in C2:

=JAHRE(A2;B2;1)

1: in Kalenderjahren

3

 

 

3

Formel in C3:

=JAHRE(A2;B2;0)

0: Intervall

4

 

 

3,96

Formel in C4:

=BRTEILJAHRE(A2;B2;0)

0: US-Methode (NASD), 12 Monate je 30 Tage

5

 

 

3,95

Formel in C5:

=BRTEILJAHRE(A2;B2;1)

1: genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

6

 

 

4,01

Formel in C6:

=BRTEILJAHRE(A2;B2;2)

2: genaue Anzahl Tage im Monat, Jahr hat 360 Tage

7

 

 

3,96

Formel in C7:

=BRTEILJAHRE(A2;B2;3)

3: genaue Anzahl Tage im Monat, Jahr hat 365 Tage

8

 

 

3,96

Formel in C8:

=BRTEILJAHRE(A2;B2;4)

4: Europa-Methode, 12 Monate je 30 Tage

10. Ein Datum +/- eine bestimmte Anzahl Monate

Die Funktion EDATUM() bestimmt einen Tag, der eine wählbare Anzahl von Monaten vor oder nach einem Ausgangsdatum liegt. Dabei werden nur einzelne Tage berechnet, was zu diesen Ergebnissen führt:

A

B

C

1

Ausgangsdatum

Berechnetes Datum

Formel in Spalte B

2

29.03.07

28.02.07

=EDATUM(A2;-1)

3

29.03.06

28.02.06

=EDATUM(A3;-1)

4

29.03.05

28.02.05

=EDATUM(A4;-1)

5

29.03.04

29.02.04

=EDATUM(A5;-1)

6

29.03.03

28.02.03

=EDATUM(A6;-1)

7

29.03.02

28.02.02

=EDATUM(A7;-1)

8

30.03.02

28.02.02

=EDATUM(A8;-1)

9

31.03.02

28.02.02

=EDATUM(A9;-1)

11. Was ist ein Tag, was ist ein Monat, was ist ein Jahr?

Ist vom 1.1.05 bis zum 31.12.05 nun ein Jahr vergangen oder nicht? Sind es 11 oder 12 Monate? 364 Tage oder 365?

A

B

C

D

E

1

Datum von

Datum bis

Anzahl Jahre

Anzahl Monate

Anzahl Tage

2

01.01.2005

31.12.2005

0

11

364

3

Der Sachverhalt wird klar, sobald man auf das vollständige Zeitformat wechselt:
Das bis-Datum geht von 0 Uhr aus.
(Man kann auch an den eigenen Geburtstag denken: Am Vortag gilt noch das "alte" Alter, das neue Jahr fängt erst um 24 Uhr an, bzw. um 0 Uhr des Folgetages.)

4

01.01.2005 00:00

31.12.2005 00:00

0

11

364

Zelle C2/C4

Formel: =JAHRE(A2;B2;0)
Format: 0

Zelle D2/D4

Formel: =MONATE(A2;B2;0)
Format: 0

Zelle E2/E4

Formel: =TAGE(B2;A2)
Format: 0

Wenn man das bis-Datum als vollen Tag gerechnet haben will, muss man das in der Formel berücksichtigen:

A

B

C

D

E

1

Datum von

Datum bis

Anzahl Jahre

Anzahl Monate

Anzahl Tage

2

01.01.2005

31.12.2005

1

12

365

Theoretisch könnte man einfach 1 zum bis-Datum addieren. Um sicherzugehen, filtert man jedoch aus beiden Datumsangaben das reine Datum heraus, addiert aber dann zum bis-Datum 24 Stunden.1 Das ist später auch leichter nachzuvollziehen als einfach +1:

Zelle C2

Formel: =JAHRE(DATUM(JAHR(A2);MONAT(A2);TAG(A2));
        DATUM(JAHR(B2);MONAT(B2);TAG(B2))+ZEIT(24;0;0);0)

Format: 0

Zelle D2

Formel: =MONATE(DATUM(JAHR(A2);MONAT(A2);TAG(A2));
        DATUM(JAHR(B2);MONAT(B2);TAG(B2))+ZEIT(24;0;0);0)

Format: 0

Zelle E2

Formel: TAGE(DATUM(JAHR(B2);MONAT(B2);TAG(B2))+ZEIT(24;0;0);
        DATUM(JAHR(A2);MONAT(A2);TAG(A2)))

Format: 0

12. Die Funktion UMWANDELN_ADD

Diese Funktion erlaubt es, einen Wert von einer Maßeinheit in eine andere umzurechnen. Im Bereich Zeit kann die Formel von und nach den Einheiten:

umrechnen.

In den folgenden Beispielen wurden individuelle Zellformate benutzt, um die Einheiten zu den Werten anzuzeigen.

A

B

C

D

1

Ausgangseinheit

Umgerechnet in

Formel in Spalte B

Zellformat in Spalte B

2

1 Jahr(e)

365 Tag(e)

=UMWANDELN_ADD(A2;"yr";"day")

0 [$ Tag(e)]

3

1 Jahr(e)

365,25 Tag(e)

=UMWANDELN_ADD(A3;"yr";"day")

0,00 [$ Tag(e)]

4

1 Jahr(e)

8766 Stunde(n)

=UMWANDELN_ADD(A4;"yr";"hr")

0 [$ Stunde(n)]

5

1 Jahr(e)

525960 Minute(n)

=UMWANDELN_ADD(A5;"yr";"mn")

0 [$ Minute(n)]

6

1 Jahr(e)

31557600 Sekunde(n)

=UMWANDELN_ADD(A6;"yr";"sec")

0 [$ Sekunde(n)]

7

31  Tag(e)

0,085 Jahr(e)

=UMWANDELN_ADD(A7;"day";"yr")

0,000 [$ Jahr(e)]

13. Arbeitszeit abzüglich Feiertage

Mit der Funktion NETTOARBEITSTAGE() wird die Anzahl Arbeitstage errechnet, die zwischen zwei Kalenderdaten liegt. Optional kann ein Bereich genannt werden, der eine Liste von Feiertagsdaten enthält. Diese Feiertage werden – sofern sie auf Werktage fallen – von den Arbeitstagen abgerechnet.

A

B

C

D

2

01.01.05

Neujahr

Datum von:

20.03.05

3

25.03.05

Karfreitag

Datum bis:

05.04.05

4

27.03.05

Ostersonntag

Differenz in Tagen:

16

5

28.03.05

Tag der Arbeit

Werktage:

12

6

05.05.05

Christi Himmelfahrt

Werktage abzüglich Feiertage:

10

Zelle D4

Formel: =TAGE(D3;D2)

Zelle D5

Formel: =NETTOARBEITSTAGE(D2;D3)

Zelle D6

Formel: =NETTOARBEITSTAGE(D2;D3;A2:A6)

14. Arbeitstag-Datum in der Zukunft oder Vergangenheit suchen

Mit der Funktion ARBEITSTAG() wird das Datum eines Arbeitstages ermittelt, der eine bestimmte Anzahl von Arbeitstagen von einem Ausgangsdatum entfernt liegt Optional kann ein Bereich genannt werden, der eine Liste von Feiertagsdaten enthält. Diese Feiertage werden – sofern sie auf Werktage fallen – von den Arbeitstagen abgerechnet.

A

B

C

D

2

01.01.05

Neujahr

Datum von:

20.03.05

3

25.03.05

Karfreitag

Anzahl Tage:

10

4

27.03.05

Ostersonntag

Datum:

01.04.05

5

28.03.05

Tag der Arbeit

Datum (Feiertage berücksichtigt):

05.04.05

6

05.05.05

Christi Himmelfahrt

Zelle D4

Formel: =ARBEITSTAG(D2;D3)
Format: TT.MM.JJ

Zelle D5

Formel: =ARBEITSTAG(D2;D3;A2:A6)
Format: TT.MM.JJ

15. Bruchteile von Jahren

Man kann einen Zeitraum mit einem bekannten Anfangs- und einem bekannten Enddatum als Bruchteil eines Jahres darstellen lassen. Datei gibt es verschiedene Methoden (Basis 0 bis 4 im folgenden Beispiel) der Berechnung. Die Methoden unterscheiden sich in der Definition von Jahr und Monat. Nur mit der Basis 1 wird von der genauen Anzahl Tage im Monat ausgegangen, wodurch das Ergebnis in Schaltjahren variiert. Die europäische Methode wird mit Basis 4 angewendet und geht von 30 Tagen pro Monat aus. Eine Beschreibung aller Berechnungsmethoden liefert der Hilfetext.

A

B

C

D

E

1

30.12.99

30.12.99

Basis

Jahres-Bruchteil

Formel

2

29.04.07

08.09.07

0

0,358333333333333

=BRTEILJAHRE(A2;B2;C2)

3

29.04.07

08.09.07

1

0,361643835616438

=BRTEILJAHRE(A3;B3;C3)

4

29.04.07

08.09.07

2

0,366666666666667

=BRTEILJAHRE(A4;B4;C4)

5

29.04.07

08.09.07

3

0.,361643835616438

=BRTEILJAHRE(A5;B5;C5)

6

29.04.07

08.09.07

4

0,358333333333333

=BRTEILJAHRE(A6;B6;C6)

Schaltjahr

8

29.04.04

08.09.04

0

0,358333333333333

=BRTEILJAHRE(A8;B8;C8)

9

29.04.04

08.09.04

1

0,360655737704918

=BRTEILJAHRE(A9;B9;C9)

10

29.04.04

08.09.04

2

0,366666666666667

=BRTEILJAHRE(A10;B10;C10)

11

29.04.04

08.09.04

3

0,361643835616438

=BRTEILJAHRE(A11;B11;C11)

12

29.04.04

08.09.04

4

0,358333333333333

=BRTEILJAHRE(A12;B12;C12)

16. Mitternacht

Zeitangaben, die über Mitternacht hinausgehen, sind tückisch. Im nachstehenden Beispiel sehen Sie in den Zeilen mit einem * was sich tatsächlich hinter der Zeit in der darüberliegenden Zelle verbirgt. Und welchen Unterschied die Zeitformate [HH] und HH aufweisen.

 

A

B

C

D

E

F

1

ANFANG

ENDE

DIFFERENZ
ENDE – ANFANG

Formeln
in Spalte D

Format in Spalte D

2

23:00

01:45

02:45

=C2-B2

HH:MM

3

*

23:00:00

01:45:00

-21:15

=C2-B2

[HH]:MM

4

23:00

01:45

02:45

=C4-B4

HH:MM

5

*

01.12.2004 23:00:00

02.12.2006 01:45:00

02:45

=C4-B4

[HH]:MM

6

23:00

01:45

26:45

=C6-B6

HH:MM

7

*

01.12.2004 23:00:00

03.12.2006 01:45:00

02:50

=C6-B6

[HH]:MM

Spätestens, wenn man ein solches Ergebnis bekommt, wird klar, dass nicht nur ein Formatproblem vorliegt, sondern auch ein logisches:

 

A

B

C

D

1

von

bis

DIFFERENZ
bis - von

Formeln
in Spalte C

2

23:00

01:45

02:45

=B2-A2

3

23:00

01:45

02:45

=B3-A3

4

 

 

-42:30:00

=SUMME(C2:C3)

Ein Zeitwert ist immer Teil eines Datumswertes. Gibt man in eine Zelle nur eine Zeit ohne Datum ein, so geht Calc von einem zugehörigen Datum 0 aus. Welches Datum zum Tag 0 gehört, ist unter Extras → Optionen → OpenOffice.org Calc → Berechnen definiert, standardmäßig ist das der 30.12.1899.

Wenn man die Zeitwerte im obigen Beispiel mit dem Format
TT.MM.JJJJ HH:MM
anzeigen lässt, so erhält man:
von: 30.12.1899 23:00 bis 30.12.1899 01:45
woraus klar wird, dass die bis-Zeit kleiner als die von-Zeit ist.

Man kann die Zeiten auch als Zahl anzeigen lassen und erhält:
von: 0.96 bis: 0.07
woraus ebenfalls hervorgeht, dass die bis-Zeit kleiner ist als die von-Zeit.

Um nun eine korrekte Differenz zu bekommen, gibt es zwei Möglichkeiten. Entweder man integriert das Datum. Das kann in der gleichen Zelle geschehen, man kann direkt eintippen:
01.07.2007 18:00:00
oder man führt für "von" und "bis" jeweils zwei Spalten, eine mit dem Datum und eine mit der Zeit.

 

A

B

C

D

E

F

G

1

von

bis

DIFFERENZ
bis - von

Formel
in Spalte F

2

01.07.07

23:00

02.07.07

01:45

02:45

=(D2+E2)-(B2+C2)

Die Einbeziehung des Datums hat den Vorteil, dass nun zwischen der von-Zeit und der bis-Zeit eine beliebige Anzahl Stunden liegen kann, also auch mehr als 24.

Wenn man sicher ist, dass zwischen von und bis weniger als 24 Stunden liegen, kann man auf das Datum verzichten und stattdessen die Formel für die Ermittlung der Differenz anpassen:

 

A

B

C

D

E

1

von

bis

DIFFERENZ
bis - von

Formel
in Spalte D

2

23:00

01:45

02:45

=(24:00:00-B2)+C2

Und da 24:00:00 für Calc gleichbedeutend ist mit 1, kann man auch schreiben: =(1-B2)+C2

Wenn man nicht davon ausgehen kann, dass zwischen der von- und der bis-Zeit Mitternacht liegt, packt man das Ganze in eine WENN-Funktion:
=WENN(C2<B2;(1-B2)+C2;C2-B2)

17. Schaltjahre

Es gibt mehrere Funktionen, welche im Zusammenhang mit Schaltjahren verwendet werden können.

Die Funktion =ISTSCHALTJAHR(Datum) liefert einen Wahrheitswert.

Mit den Funktionen =TAGEIMJAHR(Datum) und =TAGEIMMONAT(Datum) erhält man die jeweilige Anzahl Tage und kann daraus schließen, ob es sich um ein Schaltjahr handelt oder nicht.

Beispiele:

=TAGEIMMONAT(DATUM(2004;2;1))
 Ergebnis: 29
=TAGEIMJAHR(HEUTE())
 Ergebnis: je nach Jahr 365 oder 366
=TAGEIMMONAT(MONATSENDE(DATUM(2004;1;1);1))
 Ergebnis: 29
=ISTSCHALTJAHR(HEUTE())
 Ergebnis: je nach Jahr FALSCH oder RICHTIG bzw. 0 oder 1


KategorieHowto KategorieCalc

  1. In AOO ab Version 3.4 liefert die Funktion ZEIT() einen Wert zwischen 00:00:00 und 23:59:59.999 (zuvor lieferte die Funktion auch Werte von größer oder gleich 24:00:00.0). Die folgenden Beispiele sind deshalb nicht gültig für AOO. (1)


LizenzBedingungen | AnbieterKennzeichnung | DatenschutzErklärung | Stand: 2013-04-28