Aus dem aktuellen Jahr und dem Ostersonntag, für den Calc eine Funktion zur Verfügung stellt, lassen sich alle weiteren Feiertage ermitteln. Im Beispiel erhalten die Zellen B2 und B3 einen Namen, der in den weiteren Formeln anstelle der Zelladresse verwendet wird.

1.1. Formeln für die wichtigsten Feiertage

1.2. Der vierte Advent und der davon abgeleitete Buß- und Bettag

Bei der Berechnung des vierten Advents (diesen benötigt man auch für die Errechnung des Buß- und Bettages) haben wir das Problem, dass dieser nicht auf ein fixes Datum fällt, sondern per Definition auf den letzten Sonntag vor dem 25. Dezember, d.h. Jedes Jahr ein anderes Datum hat.

Was wissen wir von diesem Datum?

Fällt der 25. Dezember auf einen Montag, dann führt ((25. Dezember) – 1) zum vierten Advent.
Fällt der 25. Dezember auf einen Dienstag, dann führt ((25. Dezember) – 2) zum vierten Advent.
Fällt der 25. Dezember auf einen Mittwoch, dann führt ((25. Dezember) – 3) zum vierten Advent.
Fällt der 25. Dezember auf einen Donnerstag, dann führt ((25. Dezember) – 4) zum vierten Advent.
Fällt der 25. Dezember auf einen Freitag, dann führt ((25. Dezember) – 5) zum vierten Advent.
Fällt der 25. Dezember auf einen Samstag, dann führt ((25. Dezember) – 6) zum vierten Advent.
Fällt der 25. Dezember auf einen Sonntag, dann führt ((25. Dezember) – 7) zum vierten Advent.

Wir müssen also wissen, auf welchen Wochentag der 25. Dezember fällt. Die Funktion WOCHENTAG() liefert uns zu jedem Datum eine fortlaufende Nummer von 1 bis 7. Jetzt müssen wir nur noch wissen, zu welchem Wochentag die Wochentagsnummer 1 gehört.

Das können wir selbst bestimmen. Benutzen wir die Funktion mit den Standardwerten, also so:

=WOCHENTAG(Datum)

dann ist der erste Tag in der Woche ein Sonntag. Benutzen wir jedoch den zweiten Parameter der Formel:

=WOCHENTAG(Datum;2)

dann beginnt die Zählung am Montag, was uns das Leben sehr erleichtert. Denn wir wissen aus obiger Auflistung, dass wir am Montag - 1 rechnen müssen, am Dienstag - 2, usw.

Der vierte Advent ist also:

=25. Dezember – WOCHENTAG(25. Dezember;2)

Gehen wir davon aus, dass die Daten für das aktuelle Jahr berechnet werden sollen, so steht für den 25. Dezember:

=DATUM(JAHR(HEUTE());12;25)

Soll das Jahr flexibel sein, kann man es beispielsweise auch in einer Zelle oder einem Namen hinterlegen, dann könnte die Formel für den 25. Dezember so lauten:

=DATUM(Kalenderjahr;12;25)

Und nun heißt die Formel für den vierten Advent:

=DATUM(KalenderJahr;12;25)-WOCHENTAG(DATUM(KalenderJahr;12;25);2)

Für den dritten Advent werden zusätzliche 7 Tage abgezogen, für den zweiten 14 und für den ersten Advent 21 Tage:

=DATUM(KalenderJahr;12;25)-WOCHENTAG(DATUM(KalenderJahr;12;25);2)-7

=DATUM(KalenderJahr;12;25)-WOCHENTAG(DATUM(KalenderJahr;12;25);2)-14

=DATUM(KalenderJahr;12;25)-WOCHENTAG(DATUM(KalenderJahr;12;25);2)-21

Für den Buß- und Bettag müssen vom vierten Advent 32 Tage abgezogen werden:

=DATUM(KalenderJahr;12;25)-WOCHENTAG(DATUM(KalenderJahr;12;25);2)-32

1.3. Immer am vierten Montag im November...

...findet der traditionsreiche Berner Zibelemärit (Zwiebelmarkt) statt. Er dient hier als Beispiel, wie man das Datum eines variablen Jahrestages ermittelt. Bereits bei der Berechnung der Adventstage im vorigen Kapitel hatten wir ein ähnliches Beispiel.

Vom vierten Montag im November wissen wir genau, dass er 3*7=21 Tage nach dem ersten Montag stattfindet. Also interessiert uns zunächst der erste Montag im November. Für den Fall, dass der erste November ein Montag ist, kennen wir das Datum:

=Datum(Kalenderjahr;11;1)

wobei Kalenderjahr z.B. für eine Zelle steht, in welcher das gesuchte Jahr hinterlegt ist. Wenn es um das aktuelle Jahr geht, könnte auch stehen:

=Datum(Kalenderjahr(HEUTE());11;1)

Wenn der erste November kein Montag ist, müssen wir das Datum für den ersten Montag erst suchen. Dazu sehen wir uns die Liste an, die wir mit der Funktion =WOCHENTAG(Datum;2) für jeden Tag der Woche erhalten:

Dienstag ergibt 2, Mittwoch 3, usw. bis zum Sonntag, der bei der obigen Variante der WOCHENTAG-Funktion 7 ergibt ¹. Daraus ergibt sich folgende Regel:

Fällt der 1. November auf einen Dienstag, so müssen wir zum 1.11. 6 Tage hinzuzählen, um das Datum des ersten Montags im Novembers zu erhalten, fällt der 1.11. auf einen Mittwoch, müssen wir 5 Tage hinzuzählen, usw..

Man könnte nun eine verschachtelte WENN-Formel aufbauen, welche all diese Situationen abfragt. Schöner wäre allerdings, man fände eine Rechenformel, die für alle Nicht-Montage angewendet werden kann. Aus der nachstehenden Tabelle sehen wir, dass die Summe aus der Zahl, die wir jeweils mit der WOCHENTAG-Funktion erhalten und der Zahl, die hinzugezählt werden muss, um auf den folgenden Montag zu kommen, für alle Wochentage außer Montag 8 ergibt.

Wenn wir also vom Ergebnis 8 ausgehen, sehen wir, dass die Differenz für alle Nicht-Montage gleich berechnet werden kann:

8-WOCHENTAG(Datum(Kalenderjahr;11;1);2)

Somit heißt unsere Formel für den vierten Montag im November:

=WENN(WOCHENTAG(DATUM(Kalenderjahr;11;1);2)=1;
  DATUM(Kalenderjahr;11;1)+3*7;
    DATUM(Kalenderjahr;11;1)+8-WOCHENTAG(DATUM(Kalenderjahr;11;1);2)+3*7)

---

KategorieCalc KategorieHowto

3. Zu einem bestimmten Wochentag vor- bzw. zurückrechnen

Manchmal braucht man im Zusammenhang mit Datumsfunktionen eine Formel, die ausgehend von einem variablen Datum immer z.B. den nächsten (oder letzten) Donnerstag, Mittwoch oder sonst einen bestimmten Wochentag liefert.

3.1. Zum nächsten Montag (Dienstag, Mittwoch,....)

Da unser Ausgangsdatum variabel ist, müssten wir theoretisch 7 WENN-Fälle unterscheiden. Solche verschachtelten Funktionen sind aber schwierig zu dominieren und wenn die Formel auch noch dahingehend flexibel sein soll, dass sie auf verschiedene angestrebte Wochentage reagiert, wird das Ganze sehr unübersichtlich. Wir suchen daher nach einer mathematischen Lösung.

Wir haben:

• ein unbekanntes Ausgangsdatum
• einen fixen angestrebten Wochentag
• einen unbekannten Ausgangs-Wochentag

Nun wissen wir, dass wir mit einer mathematischen Gleichung nur eine Unbekannte ermitteln können. Wir müssen also versuchen, in dieser Liste eine Unbekannte wegzubekommen. Das Ausgangsdatum ist per Definition variabel, also die Unbekannte, die uns in jedem Fall bleibt. Was aber ist mit dem Ausgangs-Wochentag? Kann man den zu einer bekannten Größe machen?
Man kann:

Nachdem wir nun für unsere Vorwärtszählung nicht von einem beliebigen Wochentag ausgehen, sondern immer vom davorliegenden Samstag, wissen wir stets, was wir hinzuzählen müssen, um zum tatsächlich angestrebten Wochentag zu gelangen:

Die Problemfälle sind in der oberen Tabelle hervorgehoben: Immer, wenn der angestrebte Wochentag mit dem Wochentag des Ausgangsdatums übereinstimmt, gelangen wir zum Ausgangsdatum anstatt zum entsprechenden Datum der kommenden Woche.

Nun könnte man versuchen, diesen Fall durch eine WENN-Abfrage in den Griff zu bekommen. Es geht aber auch eleganter.

Die Situation, die wir bisher haben ist die, dass wir maximal um 7 Tage zurückrechnen und anschließend maximal um 7 Tage vorwärts. Wir lösen das Problem, indem wir fix um 8 Tage vorwärts rechnen. Das bedeutet aber, dass wir die Formel anders aufbauen müssen.

Bisher haben wir uns einen fixen Startpunkt gesucht - immer der letzte Samstag – zu dem wir je nachdem 1, 2,...7 Tage hinzugezählt haben. Da wir jetzt fix 8 Tage hinzuzählen wollen, muss also der Startpunkt variabel werden und nicht auf den Samstag fixiert:

3.1.1. Anwendungsbeispiele

Für die Erklärung des Formelaufbaus haben wir je nach Wochentag einen fixen Wert benutzt:
$A2-WOCHENTAG($A2-1)+8 → zum nächsten Montag
$A2-WOCHENTAG($A2-2)+8 → zum nächsten Dienstag
$A2-WOCHENTAG($A2-3)+8 → zum nächsten Mittwoch
usw.

Vielleicht ist der angestrebte Wochentag aber nicht immer der gleiche. Dann könnte man z.B. eine Zelle benutzen, in die man den jeweils zu benutzenden Wert hinterlegt, dann könnte die Formel so aussehen:
$A2-WOCHENTAG($A2-$A$1)+8³

Oder man hinterlegt in dieser Zelle keine Werte, sondern die Wochentage: Mo, Di, Mi, usw. Dann müsste man eine WENN-Formel einbauen:

=WENN($A$1="Mo";1; WENN($A$1="Di";2; WENN($A$1="Mi";3; WENN($A$1="Do";4; WENN($A$1="Fr";5; WENN($A$1="Sa";6;7))))))

Die ganze Formel würde dann so aussehen:

$A2-WOCHENTAG($A2-WENN($A$1="Mo";1; WENN($A$1="Di";2; WENN($A$1="Mi";3; WENN($A$1="Do";4; WENN($A$1="Fr";5; WENN($A$1="Sa";6;7)))))))

Statt WENN-Formeln könnte man auch mit der Funktion SVERWEIS() arbeiten.

3.2. Zum letzten Montag (Dienstag, Mittwoch,....)

Im vorigen Beispiel mussten wir zuerst zurückrechnen und anschließend wieder vorwärtsrechnen, wodurch wir das Problem lösen mussten, dass die Anzahl zurückgerechneter Tage nicht gleich sein durfte wie die Anzahl vorwärtsgerechneter Tage.

Wenn wir einen zurückliegenden Wochentag suchen, haben wir es leichter:

(Datum-WOCHENTAG(Datum)) → zum letzten Samstag
(Datum-WOCHENTAG(Datum+1)) → zum letzten Freitag
(Datum-WOCHENTAG(Datum+2)) → zum letzten Donnerstag

Auch hier kann natürlich der Ausdruck +1, +2, usw. ersetzt werden durch einen Zellbezug oder eine WENN-Formel wie in den obigen Anwendungsbeispielen beschrieben.

3.3. Der erste Montag von jedem Monat des laufenden Jahres

Das folgende Beispiel geht davon aus, dass das aktuelle Jahr in einer benannten Zelle hinterlegt ist, und man sich mit der Bezeichnung AktuellesJahr darauf beziehen kann. Die Jahreszahl kann dabei direkt oder in der Form =JAHR(HEUTE()) gespeichert sein. Die hier verwendete Bezeichung AktuellesJahr kann natürlich auch durch eine Zelladresse oder eine Formel ersetzt werden.

Der jeweils erste Dienstag:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();5)

Der jeweils erste Mittwoch:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();4)

Der jeweils erste Donnerstag:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();3)

Der jeweils erste Freitag:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();2)

Der jeweils erste Samstag:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();8)

Der jeweils erste Sonntag:
=DATUM(AktuellesJahr;ZEILE();8)-WOCHENTAG(DATUM(AktuellesJahr;ZEILE();7)

3.4. Samstag/Sonntag auslassen

Das folgende Beispiel ergibt einen Kalender, der jeden Monat mit dem ersten Montag dieses Monats beginnt und nur die Wochentage berücksichtigt.

Um den jeweils ersten Montag pro Monat zu ermitteln gehen wir wie oben beschrieben vom jeweils 8. des Monats aus und rechnen zurück. Dieses Datum – der 8. des Monats – verwenden wir gleich als Spaltentitel und ordnen den Zellen in Zeile 1 das Zahlenformat: MMMM JJJJ zu.

Im Beispiel steht in Spalte 1 der Januar, in Spalte 2 der Februar, etc. Also können wir die Spaltennummer benutzen, um den jeweiligen Monat festzulegen. Wir gehen davon aus, dass es um das aktuelle Jahr gehen soll, daher definiert sich das Jahr mit der Formel =JAHR(HEUTE()). Die ganze Formel in allen Zellen der ersten Zeile lautet also:
=DATUM(JAHR(HEUTE());SPALTE();8)

Die Formel in A2 lautet:
=A1-WOCHENTAG(A1+5)
Diese Formel kann nun nach rechts kopiert werden.

In A3 muss eigentlich nur gerechnet werden: =A2+1. Dann können wir diese Formel aber nur zweimal kopieren und müssen sie am Freitag anpassen und 3 statt 1 hinzu zählen. Also erweitern wir die Formel in A3 auf:
=A2+1+WENN(WOCHENTAG(A2)=6;2) Diese Formel kann nun nach unten und rechts kopiert werden.

3.4.1. Jahreswechsel

Wir haben beim obigen Kalender die Spaltennummer benutzt, um den aktuellen Monat zu ermitteln. Wenn Sie nun denken, bei Spalte 12 sei Schluss, so irren Sie. Die Funktion DATUM() ist intelligenter als es auf den ersten Blick scheint:

Man kann den obigen Kalender getrost weiter nach rechts kopieren:

Siehe auch: Datum

3.5. Der jeweils letzte Montag, Dienstag,... des Monats

Das folgende Beispiel geht davon aus, dass das laufende Jahr als Basis dienen soll und der Monat aus der Spaltennummer ermittelt wird (vgl. oben). Wenn das Basisdatum anders ermittelt wird, sind die Parameter Jahr, Monat, Tag der Funktion DATUM() entsprechend anzupassen.

Für die Ermittlung des letzten Montags (Dienstags, Mittwochs,...) des laufenden Monats gehen wir vom Folgemonat aus (daher SPALTE()+1). Wir machen uns die Tatsache zu nutze, dass ein Datum, von dem wir seine Wochentags-Nummer abziehen, uns zum davor liegenden Samstag führt (siehe oben). Wenn wir also vom ersten Tag des Folgemonats den Wochentag dieses Monatsersten abziehen, erhalten wir den letzten Samstag des laufenden Monats.

Für alle anderen gesuchten Wochentage ziehen wir vom Monatsersten des Folgemonats nicht den Wochentag des Monatsersten ab, sondern verschieben ihn gemäss folgender Tabelle:

---

KategorieCalc KategorieHowto

Zeitwerte rechnen (wie Datumswerte) in ganzen Tagen. Das wird offensichtlich, wenn man einen Zeitwert durch 1 dividiert (A1 sei 12:00 und B2=A1/1, das Resultat ist 0,5)

4.1. Stunden addieren und in Dezimalzahlen umrechnen

Wenn Zeitwerte z.B. mit einem Stundenansatz multipliziert werden sollen, werden sie als Dezimalwert benötigt.

Aus einem Zeitwert wird durch die Multiplikation mit 24 ein dezimaler Stundenbetrag.
Aus einem Zeitwert wird durch die Multiplikation mit 24*60 ein dezimaler Minutenbetrag.
Aus einem Zeitwert wird durch die Multiplikation mit 24*60*60 ein dezimaler Sekundenbetrag.

4.2. Minuten und Sekunden, Differenz im Zeit- oder Dezimalformat

Im vorigen Beispiel wurden Stunden durch die Multiplikation mit 24 in einen Dezimalwert umgerechnet. Bei Minuten muss zusätzlich mit 60 multipliziert werden. Im folgenden wird die Differenz zwischen zwei Zeiten errechnet und sowohl im Zeit- wie auch Dezimalformat ausgegeben, um z.B. Telefonkosten abzurechnen.

Bitte auch hier den Unterschied zwischen dem Format [HH]:MM:SS und HH:MM:SS bedenken (vgl. oben).

4.3. JAHR(), MONAT(), TAG(), STUNDE(), MINUTE(), SEKUNDE()

Mit diesen Funktionen kann man aus einem Datums- und/oder Zeitwert die gewünschten Details herausfiltern.

=JAHR(HEUTE())

ergibt beispielsweise die zum aktuellen Datum passende Jahreszahl vierstellig aus.

=MINUTE(JETZT())

ergibt die Minuten der aktuellen Uhrzeit.

ACHTUNG: Diese Funktionen liefern nicht die tatsächliche Anzahl z.B. von Stunden.

Beispiel: Aus einer Zeitspalte wird die Summe gebildet und ergibt 24:44:00, also 24 Stunden und 44 Minuten. Wenn man auf diesen Wert die Funktion STUNDE() anwendet, so ergibt sich:

=STUNDE(24:44:00) -> Ergebnis: 0

STUNDE() wird als Zahl zwischen 0 und 23 wiedergegeben. Ab 24 Stunden wird wieder bei 0 angefangen. Die tatsächliche Anzahl an Stunden muss man also anders berechnen, wie z.B.:

=GANZZAHL(24:44:00*24)
bzw.
=GANZZAHL(ZelleMitZeitwert*24)

4.4. Stunden und Tage, arbeiten mit verschiedenen Formaten

4.5. Stunden, Tage, Minuten getrennt

4.6. Datum und Zeit aus verschiedenen Zellen

4.7. Anzahl Tage zwischen zwei Datumsangaben

4.8. Anzahl Monate zwischen zwei Datumsangaben

4.9. Anzahl Jahre zwischen zwei Datumsangaben

4.10. Ein Datum +/- eine bestimmte Anzahl Monate

Die Funktion EDATUM() bestimmt einen Tag, der eine wählbare Anzahl von Monaten vor oder nach einem Ausgangsdatum liegt. Dabei werden nur einzelne Tage berechnet, was zu diesen Ergebnissen führt:

4.11. Was ist ein Tag, was ist ein Monat, was ist ein Jahr?

Ist vom 1.1.05 bis zum 31.12.05 nun ein Jahr vergangen oder nicht? Sind es 11 oder 12 Monate? 364 Tage oder 365?

Wenn man das bis-Datum als vollen Tag gerechnet haben will, muss man das in der Formel berücksichtigen:

Theoretisch könnte man einfach 1 zum bis-Datum addieren. Um sicherzugehen, filtert man jedoch aus beiden Datumsangaben das reine Datum heraus, addiert aber dann zum bis-Datum 24 Stunden.⁴ Das ist später auch leichter nachzuvollziehen als einfach +1:

4.12. Die Funktion UMWANDELN_ADD

Diese Funktion erlaubt es, einen Wert von einer Maßeinheit in eine andere umzurechnen. Im Bereich Zeit kann die Formel von und nach den Einheiten:

• Jahr: yr

• Tag: day

• Stunde: hr

• Minute: mn

• Sekunde: sec

umrechnen.

In den folgenden Beispielen wurden individuelle Zellformate benutzt, um die Einheiten zu den Werten anzuzeigen.

4.13. Arbeitszeit abzüglich Feiertage

Mit der Funktion NETTOARBEITSTAGE() wird die Anzahl Arbeitstage errechnet, die zwischen zwei Kalenderdaten liegt. Optional kann ein Bereich genannt werden, der eine Liste von Feiertagsdaten enthält. Diese Feiertage werden – sofern sie auf Werktage fallen – von den Arbeitstagen abgerechnet.

4.14. Arbeitstag-Datum in der Zukunft oder Vergangenheit suchen

Mit der Funktion ARBEITSTAG() wird das Datum eines Arbeitstages ermittelt, der eine bestimmte Anzahl von Arbeitstagen von einem Ausgangsdatum entfernt liegt Optional kann ein Bereich genannt werden, der eine Liste von Feiertagsdaten enthält. Diese Feiertage werden – sofern sie auf Werktage fallen – von den Arbeitstagen abgerechnet.

4.15. Bruchteile von Jahren

Man kann einen Zeitraum mit einem bekannten Anfangs- und einem bekannten Enddatum als Bruchteil eines Jahres darstellen lassen. Datei gibt es verschiedene Methoden (Basis 0 bis 4 im folgenden Beispiel) der Berechnung. Die Methoden unterscheiden sich in der Definition von Jahr und Monat. Nur mit der Basis 1 wird von der genauen Anzahl Tage im Monat ausgegangen, wodurch das Ergebnis in Schaltjahren variiert. Die europäische Methode wird mit Basis 4 angewendet und geht von 30 Tagen pro Monat aus. Eine Beschreibung aller Berechnungsmethoden liefert der Hilfetext.

4.16. Mitternacht

Zeitangaben, die über Mitternacht hinausgehen, sind tückisch. Im nachstehenden Beispiel sehen Sie in den Zeilen mit einem * was sich tatsächlich hinter der Zeit in der darüberliegenden Zelle verbirgt. Und welchen Unterschied die Zeitformate [HH] und HH aufweisen.

Ein Zeitwert ist immer Teil eines Datumswertes. Gibt man in eine Zelle nur eine Zeit ohne Datum ein, so geht Calc von einem zugehörigen Datum 0 aus. Welches Datum zum Tag 0 gehört, ist unter Extras → Optionen → OpenOffice.org Calc → Berechnen definiert, standardmäßig ist das der 30.12.1899.

Wenn man die Zeitwerte im obigen Beispiel mit dem Format
TT.MM.JJJJ HH:MM
anzeigen lässt, so erhält man:
von: 30.12.1899 23:00 bis 30.12.1899 01:45
woraus klar wird, dass die bis-Zeit kleiner als die von-Zeit ist.

Man kann die Zeiten auch als Zahl anzeigen lassen und erhält:
von: 0.96 bis: 0.07
woraus ebenfalls hervorgeht, dass die bis-Zeit kleiner ist als die von-Zeit.

Um nun eine korrekte Differenz zu bekommen, gibt es zwei Möglichkeiten. Entweder man integriert das Datum. Das kann in der gleichen Zelle geschehen, man kann direkt eintippen:
01.07.2007 18:00:00
oder man führt für "von" und "bis" jeweils zwei Spalten, eine mit dem Datum und eine mit der Zeit.

Die Einbeziehung des Datums hat den Vorteil, dass nun zwischen der von-Zeit und der bis-Zeit eine beliebige Anzahl Stunden liegen kann, also auch mehr als 24.

Wenn man sicher ist, dass zwischen von und bis weniger als 24 Stunden liegen, kann man auf das Datum verzichten und stattdessen die Formel für die Ermittlung der Differenz anpassen:

Und da 24:00:00 für Calc gleichbedeutend ist mit 1, kann man auch schreiben: =(1-B2)+C2

Wenn man nicht davon ausgehen kann, dass zwischen der von- und der bis-Zeit Mitternacht liegt, packt man das Ganze in eine WENN-Funktion:
=WENN(C2<B2;(1-B2)+C2;C2-B2)

4.17. Schaltjahre

Es gibt mehrere Funktionen, welche im Zusammenhang mit Schaltjahren verwendet werden können.

Die Funktion =ISTSCHALTJAHR(Datum) liefert einen Wahrheitswert.

Mit den Funktionen =TAGEIMJAHR(Datum) und =TAGEIMMONAT(Datum) erhält man die jeweilige Anzahl Tage und kann daraus schließen, ob es sich um ein Schaltjahr handelt oder nicht.

Beispiele:

=TAGEIMMONAT(DATUM(2004;2;1))
 Ergebnis: 29
=TAGEIMJAHR(HEUTE())
 Ergebnis: je nach Jahr 365 oder 366
=TAGEIMMONAT(MONATSENDE(DATUM(2004;1;1);1))
 Ergebnis: 29
=ISTSCHALTJAHR(HEUTE())
 Ergebnis: je nach Jahr FALSCH oder RICHTIG bzw. 0 oder 1

---

KategorieHowto KategorieCalc

Vielleicht haben Sie die Funktion DATUM() auch schon benutzt, um Kalender aufzubauen und dabei im Parameter Monat Werte zwischen 1 und 12 und im Parameter Tag Werte zwischen 1 und 31 eingesetzt.

Interessant ist diese Funktion aber vor allem dann, wenn die Parameter für Monat und Tag per Formel variabel gestaltet werden können, etwa mit den Funktionen ZEILE() oder SPALTE().

Und hier zeigt sich dann die große Flexibilität der Formel. Anders, als man vielleicht annehmen würde, ist der Monat-Parameter nicht auf 1 bis 12, der Tagesparameter nicht auf 1 bis 31 beschränkt. Hier ein paar Beispiele:

Auch rückwärts rechnet die Funktion logisch:

---

KategorieTipps KategorieCalc